Je suis un débutant à CMAKE. Vous trouverez ci-dessous un simple fichier cmake qui fonctionne bien dans les fenêtres d'environnement mingw. Le problème est clairement avectarget_link_libraries() fonction de CMAKE où je lie libwsock32.a. Dans Windows, cela fonctionne et j'obtiens les résultats.

Cependant, comme prévu, sous Linux, le /usr/bin/ldcherchera -lwsock32ce qui n'est PAS là sur le système d'exploitation Linux.

Mon problème est le suivant: comment demander à CMAKE d'éviter de lier la bibliothèque wsock32 sous Linux OS ???

Toute aide sera fortement appréciée.

Mon fichier CMake simple:

 PROJECT(biourl)
 set (${PROJECT_NAME}_headers ./BioSocketAddress.h  ./BioSocketBase.h ./BioSocketBuffer.h ./BioSocketCommon.h  ./BioSocketListener.h  ./BioSocketPrivate.h  ./BioSocketStream.h ./BioUrl.h BioDatabase.h )

set (${PROJECT_NAME}_sources BioSocketAddress.C  BioSocketBase.C  BioSocketCommon.C BioSocketStream.C  BioUrl.C BioDatabase.C )

add_library(${PROJECT_NAME} STATIC ${${PROJECT_NAME}_headers} ${${PROJECT_NAME}_sources} )

# linkers
#find_library(ws NAMES wsock32 PATHS ${PROJECT_SOURCE_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_DEFAULT_PATH)

target_link_libraries(${PROJECT_NAME} bioutils wsock32)

install (TARGETS ${PROJECT_NAME}
       RUNTIME DESTINATION bin
       LIBRARY DESTINATION lib
       ARCHIVE DESTINATION lib/archive )

Utilisation

if (WIN32)
    #do something
endif (WIN32)

ou

if (UNIX)
    #do something
endif (UNIX)

ou

if (MSVC)
    #do something
endif (MSVC)

ou similaire

voir Variables utiles CMake et plateforme de vérification CMake

Étant donné qu'il s'agit d'un problème si courant, geronto-posting:

    if(UNIX AND NOT APPLE)
        set(LINUX TRUE)
    endif()

    # if(NOT LINUX) should work, too, if you need that
    if(LINUX) 
        message(STATUS ">>> Linux")
        # linux stuff here
    else()
        message(STATUS ">>> Not Linux")
        # stuff that should happen not on Linux 
    endif()

Documentation sur la logique booléenne CMake

Noms des plateformes CMake, etc.

En général

Vous pouvez détecter et spécifier des variables pour plusieurs systèmes d'exploitation comme celui-ci:

Détecter Microsoft Windows

if(WIN32)
    # for Windows operating system in general
endif()

Ou:

if(MSVC OR MSYS OR MINGW)
    # for detecting Windows compilers
endif()

Détecter Apple MacOS

if(APPLE)
    # for MacOS X or iOS, watchOS, tvOS (since 3.10.3)
endif()

Détecter Unix et Linux

if(UNIX AND NOT APPLE)
    # for Linux, BSD, Solaris, Minix
endif()

Votre problème d'éditeur de liens spécifique

Pour résoudre votre problème avec la wsock32bibliothèque spécifique à Windows , supprimez-la simplement des autres systèmes, comme ça:

if(WIN32)
    target_link_libraries(${PROJECT_NAME} bioutils wsock32)
else
    target_link_libraries(${PROJECT_NAME} bioutils)
endif()

Vous avez quelques mots spéciaux de CMAKE, jetez un œil:

if(${CMAKE_SYSTEM_NAME} STREQUAL "Linux")
    // do something for Linux
else
    // do something for other OS

Les expressions génératrices sont également possibles:

target_link_libraries(
    target_name
    PUBLIC
        libA
        $<$<PLATFORM_ID:Windows>:wsock32>
    PRIVATE
        $<$<PLATFORM_ID:Linux>:libB>
        libC
)

Cela liera libA, wsock32 et libC sous Windows et reliera libA, libB et libC sous Linux

Expressions du générateur CMake

Essayez ça:

if(WIN32)
    set(ADDITIONAL_LIBRARIES wsock32)
else()
    set(ADDITIONAL_LIBRARIES "")
endif()

target_link_libraries(${PROJECT_NAME} bioutils ${ADDITIONAL_LIBRARIES})

Vous pouvez trouver d'autres variables utiles ici .

Je veux laisser cela ici car j'ai eu du mal avec cela lors de la compilation pour Android sous Windows avec le SDK Android.

CMake fait la distinction entre la plate-forme TARGET et HOST.

Mon TARGET était Android, donc les variables comme CMAKE_SYSTEM_NAME avaient la valeur "Android" et la variable WIN32 de l'autre réponse ici n'était pas définie. Mais je voulais savoir si mon système HOST était Windows parce que je devais faire certaines choses différemment lors de la compilation sous Windows, Linux ou IO. Pour ce faire, j'ai utilisé CMAKE_HOST_SYSTEM_NAME qui, selon moi, est à peine connu ou mentionné, car pour la plupart des gens, TARGEt et HOST sont identiques ou s'en moquent.

J'espère que cela aide quelqu'un quelque part ...

Utilisez une macro de préprocesseur pour vérifier si elle est sous Windows ou Linux. Par exemple

#ifdef WIN32
LIB= 
#elif __GNUC__
LIB=wsock32
#endif

incluez -l $ (LIB) dans votre commande de construction.

Vous pouvez également spécifier un argument de ligne de commande pour différencier les deux.