Comment remplacer plusieurs motifs à la fois par sed?

Supposons que j'ai une chaîne 'abbc' et que je souhaite remplacer:

• ab -> bc
• bc -> ab

Si j'essaye deux remplacements, le résultat n'est pas ce que je veux:

echo 'abbc' | sed 's/ab/bc/g;s/bc/ab/g'
abab

Quelle commande sed puis-je utiliser pour remplacer comme ci-dessous?

echo abbc | sed SED_COMMAND
bcab

EDIT : En fait, le texte pourrait avoir plus de 2 modèles et je ne sais pas combien de remplacements j'aurai besoin. Puisqu'il y a eu une réponse disant qu'il seds'agit d'un éditeur de flux et que ses remplacements sont avidement, je pense que je devrai utiliser un langage de script pour cela.

Peut-être quelque chose comme ça:

sed 's/ab/~~/g; s/bc/ab/g; s/~~/bc/g'

Remplacez-le ~par un caractère dont vous savez qu'il ne figurera pas dans la chaîne.

J'utilise toujours plusieurs instructions avec "-e"

$ sed -e 's:AND:\n&:g' -e 's:GROUP BY:\n&:g' -e 's:UNION:\n&:g' -e 's:FROM:\n&:g' file > readable.sql

Cela ajoutera un «\ n» avant tous les AND, GROUP BY, UNION et FROM, tandis que «&» signifie la chaîne correspondante et «\ n &» signifie que vous souhaitez remplacer la chaîne correspondante par un «\ n» avant le «correspondant» "

Voici une variante de la réponse d'ooga qui fonctionne pour plusieurs recherches et remplace les paires sans avoir à vérifier comment les valeurs peuvent être réutilisées:

sed -i '
s/\bAB\b/________BC________/g
s/\bBC\b/________CD________/g
s/________//g
' path_to_your_files/*.txt

Voici un exemple:

avant:

some text AB some more text "BC" and more text.

après:

some text BC some more text "CD" and more text.

Notez que cela \bdénote les limites des mots, ce qui empêche l' ________interférence avec la recherche (j'utilise GNU sed 4.2.2 sur Ubuntu). Si vous n'utilisez pas de recherche de limite de mot, cette technique peut ne pas fonctionner.

Notez également que cela donne les mêmes résultats que la suppression de s/________//get l'ajout && sed -i 's/________//g' path_to_your_files/*.txtà la fin de la commande, mais ne nécessite pas de spécifier le chemin deux fois.

Une variation générale à ce sujet serait d'utiliser \x0ou _\x0_de remplacer ________si vous savez qu'aucune valeur nulle n'apparaît dans vos fichiers, comme l'a suggéré jthill .

sedest un éditeur de flux. Il recherche et remplace goulûment. La seule façon de faire ce que vous avez demandé est d'utiliser un modèle de substitution intermédiaire et de le modifier à la fin.

echo 'abcd' | sed -e 's/ab/xy/;s/cd/ab/;s/xy/cd/'

Cela pourrait fonctionner pour vous (GNU sed):

sed -r '1{x;s/^/:abbc:bcab/;x};G;s/^/\n/;:a;/\n\n/{P;d};s/\n(ab|bc)(.*\n.*:(\1)([^:]*))/\4\n\2/;ta;s/\n(.)/\1\n/;ta' file

Cela utilise une table de recherche qui est préparée et conservée dans l'espace d'attente (HS), puis ajoutée à chaque ligne. Un marqueur unique (dans ce cas \n) est ajouté au début de la ligne et utilisé comme méthode pour parcourir la recherche sur toute la longueur de la ligne. Une fois que le marqueur atteint la fin de la ligne, le processus est terminé et est imprimé la table de recherche et les marqueurs jetés.

NB La table de recherche est préparée au tout début et un deuxième marqueur unique (dans ce cas :) choisi pour ne pas entrer en conflit avec les chaînes de substitution.

Avec quelques commentaires:

sed -r '
  # initialize hold with :abbc:bcab
  1 {
    x
    s/^/:abbc:bcab/
    x
  }

  G        # append hold to patt (after a \n)

  s/^/\n/  # prepend a \n

  :a

  /\n\n/ {
    P      # print patt up to first \n
    d      # delete patt & start next cycle
  }

  s/\n(ab|bc)(.*\n.*:(\1)([^:]*))/\4\n\2/
  ta       # goto a if sub occurred

  s/\n(.)/\1\n/  # move one char past the first \n
  ta       # goto a if sub occurred
'

Le tableau fonctionne comme ceci:

   **   **   replacement
:abbc:bcab
 **   **     pattern

Peut être une approche plus simple pour une occurrence de modèle unique, vous pouvez essayer comme ci-dessous: echo 'abbc' | sed 's / ab / bc /; s / bc / ab / 2'

Ma sortie:

 ~# echo 'abbc' | sed 's/ab/bc/;s/bc/ab/2'
 bcab

Pour plusieurs occurrences de motif:

sed 's/\(ab\)\(bc\)/\2\1/g'

Exemple

~# cat try.txt
abbc abbc abbc
bcab abbc bcab
abbc abbc bcab

~# sed 's/\(ab\)\(bc\)/\2\1/g' try.txt
bcab bcab bcab
bcab bcab bcab
bcab bcab bcab

J'espère que cela t'aides !!

Tcl a une fonction intégrée pour cela

$ tclsh
% string map {ab bc bc ab} abbc
bcab

Cela fonctionne en parcourant la chaîne un caractère à la fois en faisant des comparaisons de chaînes à partir de la position actuelle.

En perl:

perl -E '
    sub string_map {
        my ($str, %map) = @_;
        my $i = 0;
        while ($i < length $str) {
          KEYS:
            for my $key (keys %map) {
                if (substr($str, $i, length $key) eq $key) {
                    substr($str, $i, length $key) = $map{$key};
                    $i += length($map{$key}) - 1;
                    last KEYS;
                }
            }
            $i++;
        }
        return $str;
    }
    say string_map("abbc", "ab"=>"bc", "bc"=>"ab");
'

bcab

Voici un awkbasé sur les oogassed

echo 'abbc' | awk '{gsub(/ab/,"xy");gsub(/bc/,"ab");gsub(/xy/,"bc")}1'
bcab