Oubliez les guillemets lors de la copie depuis la cellule

Problème :
lors de la copie d'une cellule d'Excel en dehors du programme, des guillemets sont ajoutés automatiquement.

Détails :
J'utilise Excel 2007 sur une machine Windows 7. Si j'ai une cellule avec la formule suivante:

="1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2."

La sortie dans la cellule (formatée en nombre) ressemble à ceci dans Excel:

1SOME NOTES FOR LINE 1.2SOME NOTES FOR LINE 2.

Bel et bien. Mais, si je copie la cellule dans un autre programme, tel que le bloc-notes, j'obtiens des guillemets doubles ennuyeux au début et à la fin. Notez que les onglets créés par "CHAR (9)" sont conservés, ce qui est bien.

"1  SOME NOTES FOR LINE 1.  2     SOME NOTES FOR LINE 2."

Comment puis-je empêcher ces doubles guillemets d'apparaître lorsque je copie dans un autre programme? En d'autres termes, puis-je empêcher que ceux-ci soient ajoutés automatiquement lorsque la cellule est copiée dans le presse-papiers?

Si vous essayez de coller dans Word-Pad, Notepad ++ ou Word, vous n'auriez pas ce problème. Pour copier la valeur de la cellule sous forme de texte pur, pour obtenir ce que vous décrivez, vous devez utiliser une macro:

Dans le classeur où vous souhaitez que cela s'applique (ou dans votre Personal.xls si vous souhaitez utiliser sur plusieurs classeurs), placez le code suivant dans un module standard:

Code:

Sub CopyCellContents()
'create a reference in the VBE to Microsft Forms 2.0 Lib
' do this by (in VBA editor) clicking tools - > references and then ticking "Microsoft Forms 2.0 Library"
Dim objData As New DataObject
Dim strTemp As String
strTemp = ActiveCell.Value
objData.SetText (strTemp)
objData.PutInClipboard
End Sub

Pour ajouter un module standard à votre projet (classeur), ouvrez le VBE avec Alt+ F11, puis cliquez avec le bouton droit sur votre classeur dans la fenêtre de projet en haut à gauche et sélectionnez Insérer> Module. Collez le code dans la fenêtre du module de code qui s'ouvrira à droite.

De retour dans Excel, allez dans Outils> Macro> Macros et sélectionnez la macro appelée "CopyCellContents", puis choisissez Options dans la boîte de dialogue. Ici, vous pouvez attribuer la macro à une touche de raccourci (par exemple, comme CTRL+ Cpour une copie normale) - J'ai utilisé CTRL+ Q.

Ensuite, lorsque vous souhaitez copier une seule cellule dans le Bloc-notes / où que vous soyez, faites simplement Ctrl + q (ou ce que vous avez choisi), puis faites un CTRL+ Vou Édition> Coller dans la destination choisie.

Ma réponse est copiée (avec quelques ajouts) à partir de: ici

EDIT : (à partir des commentaires)

Si vous ne trouvez pas la bibliothèque Microsoft Forms 2.0 dans la liste des références, vous pouvez essayer

• à la recherche de FM20.DLL à la place (merci @Peter Smallwood)
• en cliquant sur Parcourir et en sélectionnant C:\Windows\System32\FM20.dll(Windows 32 bits) (merci @JWhy)
• en cliquant sur Parcourir et en sélectionnant C:\Windows\SysWOW64\FM20.dll (sur 64 bits)

J'ai juste eu ce problème et envelopper chaque cellule avec la CLEANfonction l'a corrigé pour moi. Cela devrait être relativement facile à faire en =CLEAN(sélectionnant votre cellule, puis en remplissant automatiquement le reste de la colonne. Après avoir fait cela, les collations dans le Bloc-notes ou tout autre programme n'avaient plus de guillemets en double.

Collez-le d'abord dans Word, puis vous pouvez le coller dans le bloc-notes et il apparaîtra sans les guillemets

Si vous souhaitez sélectionner plusieurs cellules et copier leurs valeurs dans le presse-papiers sans toutes ces citations ennuyeuses, le code suivant peut être utile. Il s'agit d'une amélioration du code donné ci-dessus à partir de user3616725.

Sub CopyCells()
 'Attach Microsoft Forms 2.0 Library: tools\references\Browse\FM20.DLL
 'Then set a keyboard shortcut to the CopyCells Macro (eg Crtl T)
 Dim objData As New DataObject
 Dim cell As Object
 Dim concat As String
 Dim cellValue As String
 CR = ""
  For Each cell In Selection
  If IsNumeric(cell.Value) Then
   cellValue = LTrim(Str(cell.Value))
  Else
   cellValue = cell.Value
  End If
  concat = concat + CR + cellValue
  CR = Chr(13)
 Next
 objData.SetText (concat)
 objData.PutInClipboard
End Sub

Ma solution lorsque j'ai rencontré le problème des citations était de supprimer les retours chariot de la fin du texte de mes cellules. En raison de ces retours chariot (insérés par un programme externe), Excel ajoutait des guillemets à la chaîne entière.

Problème possible en relation avec la réponse de "user3616725":
Im sous Windows 8.1 et il semble y avoir un problème avec le code VBA lié de la réponse acceptée de "user3616725":

Sub CopyCellContents()
 ' !!! IMPORTANT !!!:
 ' CREATE A REFERENCE IN THE VBE TO "Microsft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 ' DO THIS BY (IN VBA EDITOR) CLICKING TOOLS -> REFERENCES & THEN TICKING "Microsoft Forms 2.0 Library" OR "Microsft Forms 2.0 Object Library"
 Dim objData As New DataObject
 Dim strTemp As String
 strTemp = ActiveCell.Value
 objData.SetText (strTemp)
 objData.PutInClipboard
End Sub

Détails:
En cours d'exécution au-dessus du code et en collant le presse-papiers dans une cellule dans Excel, j'obtiens deux symboles composés de carrés avec un point d'interrogation à l'intérieur, comme ceci: ⍰⍰. Coller dans le Bloc-notes ne montre même rien.

Solution:
Après avoir cherché pendant un certain temps, j'ai trouvé un autre script VBA de l'utilisateur "Nepumuk" qui utilise l'API Windows . Voici son code qui a finalement fonctionné pour moi:

Option Explicit

Private Declare Function OpenClipboard Lib "user32.dll" ( _
    ByVal hwnd As Long) As Long
Private Declare Function CloseClipboard Lib "user32.dll" () As Long
Private Declare Function EmptyClipboard Lib "user32.dll" () As Long
Private Declare Function SetClipboardData Lib "user32.dll" ( _
    ByVal wFormat As Long, _
    ByVal hMem As Long) As Long
Private Declare Function GlobalAlloc Lib "kernel32.dll" ( _
    ByVal wFlags As Long, _
    ByVal dwBytes As Long) As Long
Private Declare Function GlobalLock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalUnlock Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function GlobalFree Lib "kernel32.dll" ( _
    ByVal hMem As Long) As Long
Private Declare Function lstrcpy Lib "kernel32.dll" ( _
    ByVal lpStr1 As Any, _
    ByVal lpStr2 As Any) As Long

Private Const CF_TEXT As Long = 1&

Private Const GMEM_MOVEABLE As Long = 2

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

Private Sub StringToClipboard(strText As String)
    Dim lngIdentifier As Long, lngPointer As Long
    lngIdentifier = GlobalAlloc(GMEM_MOVEABLE, Len(strText) + 1)
    lngPointer = GlobalLock(lngIdentifier)
    Call lstrcpy(ByVal lngPointer, strText)
    Call GlobalUnlock(lngIdentifier)
    Call OpenClipboard(0&)
    Call EmptyClipboard
    Call SetClipboardData(CF_TEXT, lngIdentifier)
    Call CloseClipboard
    Call GlobalFree(lngIdentifier)
End Sub

Pour l'utiliser de la même manière que le premier code VBA ci-dessus, changez le sous "Beispiel ()" de:

Public Sub Beispiel()
    Call StringToClipboard("Hallo ...")
End Sub

À:

Sub CopyCellContents()
    Call StringToClipboard(ActiveCell.Value)
End Sub

Et exécutez-le via le menu macro Excel comme suggéré par "user3616725" de la réponse acceptée:

De retour dans Excel, allez dans Outils> Macro> Macros et sélectionnez la macro appelée "CopyCellContents", puis choisissez Options dans la boîte de dialogue. Ici, vous pouvez affecter la macro à une touche de raccourci (par exemple, comme Ctrl + c pour une copie normale) - J'ai utilisé Ctrl + q.

Ensuite, lorsque vous souhaitez copier une seule cellule dans le Bloc-notes / où que vous soyez, faites simplement Ctrl + q (ou ce que vous avez choisi), puis faites Ctrl + v ou Édition> Coller dans la destination choisie.

Edit (21 novembre 2015):
@ commentaire de "dotctor":
Non, ce n'est sérieusement pas une nouvelle question! À mon avis, c'est un bon ajout pour la réponse acceptée car ma réponse traite des problèmes auxquels vous pouvez faire face lorsque vous utilisez le code de la réponse acceptée. Si j'avais plus de réputation, j'aurais créé un commentaire.
@ commentaire de "Teepeemm":
Oui, vous avez raison, les réponses commençant par le titre "Problème:" sont trompeuses. Remplacé par: "Problème possible en relation avec la réponse de" user3616725 ":". En guise de commentaire, j'aurais certainement écrit beaucoup plus compact.

"Si vous souhaitez sélectionner plusieurs cellules et copier leurs valeurs dans le presse-papiers sans toutes ces citations ennuyeuses" ( sans les bogues de la solution multi-cellules de Peter Smallwood) "le code suivant peut être utile." Ceci est une amélioration du code donné ci-dessus de Peter Smallwood (qui "est une amélioration du code donné ci-dessus de user3616725"). Cela corrige les bogues suivants dans la solution de Peter Smallwood:

• Erreur de compilation "Variable non définie" évitée (pour "CR" - "clibboardFieldDelimiter" ici)
• Convertissez une cellule vide en une chaîne vide par rapport à "0".
• Ajouter l'onglet (ASCII 9) vs CR (ASCII 13) après chaque cellule.
• Ajoutez un CR (ASCII 13) + LF (ASCII 10) (par rapport à CR (ASCII 13)) après chaque ligne.

REMARQUE: vous ne pourrez toujours pas copier des caractères incorporés dans une cellule qui provoqueraient une sortie du champ cible dans lequel vous collez cette cellule (c'est-à-dire Tab ou CR lors du collage dans la fenêtre d'édition de table d'Access ou SSMS).

Option Explicit

Sub CopyCellsWithoutAddingQuotes()

' -- Attach Microsoft Forms 2.0 Library: tools\references\Browse\FM20.DLL
' -- NOTE: You may have to temporarily insert a UserForm into your VBAProject for it to show up.
' -- Then set a Keyboard Shortcut to the "CopyCellsWithoutAddingQuotes" Macro (i.e. Crtl+E)

Dim clibboardFieldDelimiter As String
Dim clibboardLineDelimiter As String
Dim row As Range
Dim cell As Range
Dim cellValueText As String
Dim clipboardText As String
Dim isFirstRow As Boolean
Dim isFirstCellOfRow As Boolean
Dim dataObj As New dataObject

clibboardFieldDelimiter = Chr(9)
clibboardLineDelimiter = Chr(13) + Chr(10)
isFirstRow = True
isFirstCellOfRow = True

For Each row In Selection.Rows

    If Not isFirstRow Then
        clipboardText = clipboardText + clibboardLineDelimiter
    End If

    For Each cell In row.Cells

        If IsEmpty(cell.Value) Then

            cellValueText = ""

        ElseIf IsNumeric(cell.Value) Then

            cellValueText = LTrim(Str(cell.Value))

        Else

            cellValueText = cell.Value

        End If ' -- Else Non-empty Non-numeric

        If isFirstCellOfRow Then

            clipboardText = clipboardText + cellValueText
            isFirstCellOfRow = False

        Else ' -- Not (isFirstCellOfRow)

            clipboardText = clipboardText + clibboardFieldDelimiter + cellValueText

        End If ' -- Else Not (isFirstCellOfRow)

    Next cell

    isFirstRow = False
    isFirstCellOfRow = True

Next row

clipboardText = clipboardText + clibboardLineDelimiter

dataObj.SetText (clipboardText)
dataObj.PutInClipboard

End Sub

Pour conserver les sauts de ligne lors du collage dans le bloc-notes, remplacez cette ligne dans la macro:

strTemp = ActiveCell.Value

par:

strTemp = Replace(ActiveCell.Value, Chr(10), vbCrLf)

Veuillez utiliser la formule ci-dessous

=Clean("1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2.")

et vous obtiendrez ce que vous voulez ;-)

Vous pouvez le faire dans une macro Excel via VBA, en envoyant les résultats dans un fichier:

Sub SimpleVBAWriteToFileWithoutQuotes()
    Open "c:\TEMP\Excel\out.txt" For Output As #1
    Print #1, Application.ActiveSheet.Cells(2, 3)
    Close #1
End Sub

Et si vous souhaitez obtenir les noms de fichiers et le contenu dans plusieurs fichiers, voici un court extrait qui évite les guillemets doubles autour de la sortie.

Sub DumpCellDataToTextFilesWithoutDoubleQuotes()
    ' this will work for filename and content in two different columns such as:
    ' filename column       data column
    ' 101                   this is some data
    ' 102                   this is more data

    Dim rngData As Range
    Dim strData As String
    Dim strTempFile As String
    Dim strFilename As String
    Dim i As Long
    Dim intFilenameColumn As Integer
    Dim intDataColumn As Integer
    Dim intStartingRow As Integer

    intFilenameColumn = 1     ' the column number containing the filenames
    intDataColumn = 3         ' the column number containing the data
    intStartingRow = 2        ' the row number to start gathering data


    For i = intStartingRow To Range("A1", Range("A1").End(xlDown)).Rows.Count

        ' copy the data cell's value
        Set rngData = Application.ActiveSheet.Cells(i, intDataColumn)

        ' get the base filename
        strFilename = Application.ActiveSheet.Cells(i, intFilenameColumn)

        ' assemble full filename and path
        strTempFile = "w:\TEMP\Excel\" & strFilename & ".txt"

        ' write to temp file
        Open strTempFile For Output As #1
        Print #1, rngData
        Close #1

    Next i

    ' goto home cell
    Application.ActiveSheet.Cells(1, 1).Select
    Range("A1").ClearOutline
End Sub

• si la formule a plusieurs lignes (signifie avoir un saut de ligne dans la formule), alors le copier-coller fonctionnera de cette manière
• si peut supprimer plusieurs lignes, aucun guillemet n'apparaîtra lors du copier-coller.
• sinon, utilisez la fonction CLEAN comme indiqué par @greg dans la réponse précédente

Remarque: la cause des guillemets est que lorsque les données sont déplacées d'Excel vers le Presse-papiers, elles sont entièrement conformes aux normes CSV qui incluent les valeurs de citation qui incluent des tabulations, de nouvelles lignes, etc. (et les guillemets doubles sont remplacés par deux guillemets doubles)

Donc, une autre approche, en particulier dans le cas d'OP lorsque les tabulations / nouvelles lignes sont dues à la formule, consiste à utiliser des caractères alternatifs pour les tabulations et les retours durs. J'utilise ascii Unit Separator = char (31) pour les onglets et ascii Record Separator = char (30) pour les nouvelles lignes.

Ensuite, le collage dans l'éditeur de texte n'impliquera pas les règles CSV supplémentaires et vous pouvez effectuer une recherche rapide et remplacer pour les reconvertir.

Si les onglets / nouvelles lignes sont incorporés dans les données, vous pouvez effectuer une recherche et remplacer dans Excel pour les convertir.

Qu'il s'agisse d'utiliser une formule ou de modifier les données, la clé pour choisir les délimiteurs est de ne jamais utiliser de caractères qui peuvent figurer dans les données réelles. C'est pourquoi je recommande les caractères ascii de bas niveau.

Il est également possible de supprimer ces guillemets doubles en plaçant votre résultat sur la fonction "Nettoyer".

Exemple:

=CLEAN("1"&CHAR(9)&"SOME NOTES FOR LINE 1."&CHAR(9)&"2"&CHAR(9)&"SOME NOTES FOR LINE 2.")

La sortie sera collée sans les guillemets sur d'autres programmes tels que Notepad ++.