Comment calculer automatiquement les lignes de début et de fin lors de l'inclusion de fichiers source en mode org?

J'ai ci-dessous dans ma documentation:

#+INCLUDE: "code/basic.sv" :src systemverilog :lines "14-117"

Ici, la ligne 14 est où j'ai class basic extends ..et la ligne 116 est où j'ai endclass.

Existe-t-il un moyen d'insérer automatiquement les nombres 14 et 117 (= 116 + 1) afin de ne pas avoir à les mettre à jour manuellement chaque fois que je modifie le code/basic.sv?

Voici une autre option. Celui-ci vous permet de personnaliser les expressions régulières par inclusion. Il convient mieux à certains flux de travail, car vous n'êtes pas limité aux définitions basées sur les extensions.

Utiliser

Faites quelque chose comme ce qui suit dans votre fichier d'organisation. (Le :linesmot-clé est facultatif)

#+INCLUDE: "code/my-class.sv" :src systemverilog :range-begin "^class" :range-end "^endclass" :lines "14-80"

La fonction visitera "my-class.sv" et recherchera ces deux expressions régulières, puis elle mettra à jour le :linesmot - clé en fonction du résultat de la correspondance.

S'il :range-beginmanque, la plage sera "-80".
S'il :range-endmanque, la plage sera "14-".

Le code

(add-hook 'before-save-hook #'endless/update-includes)

(defun endless/update-includes (&rest ignore)
  "Update the line numbers of #+INCLUDE:s in current buffer.
Only looks at INCLUDEs that have either :range-begin or :range-end.
This function does nothing if not in org-mode, so you can safely
add it to `before-save-hook'."
  (interactive)
  (when (derived-mode-p 'org-mode)
    (save-excursion
      (goto-char (point-min))
      (while (search-forward-regexp
              "^\\s-*#\\+INCLUDE: *\"\\([^\"]+\\)\".*:range-\\(begin\\|end\\)"
              nil 'noerror)
        (let* ((file (expand-file-name (match-string-no-properties 1)))
               lines begin end)
          (forward-line 0)
          (when (looking-at "^.*:range-begin *\"\\([^\"]+\\)\"")
            (setq begin (match-string-no-properties 1)))
          (when (looking-at "^.*:range-end *\"\\([^\"]+\\)\"")
            (setq end (match-string-no-properties 1)))
          (setq lines (endless/decide-line-range file begin end))
          (when lines
            (if (looking-at ".*:lines *\"\\([-0-9]+\\)\"")
                (replace-match lines :fixedcase :literal nil 1)
              (goto-char (line-end-position))
              (insert " :lines \"" lines "\""))))))))

(defun endless/decide-line-range (file begin end)
  "Visit FILE and decide which lines to include.
BEGIN and END are regexps which define the line range to use."
  (let (l r)
    (save-match-data
      (with-temp-buffer
        (insert-file file)
        (goto-char (point-min))
        (if (null begin)
            (setq l "")
          (search-forward-regexp begin)
          (setq l (line-number-at-pos (match-beginning 0))))
        (if (null end)
            (setq r "")
          (search-forward-regexp end)
          (setq r (1+ (line-number-at-pos (match-end 0)))))
        (format "%s-%s" l r)))))

La meilleure façon de penser est de mettre à jour ces chiffres immédiatement avant l'exportation ou avant l'évaluation.

Le programme de mise à jour

C'est la fonction qui passe par le tampon. Vous pouvez le lier à une clé ou l'ajouter à un crochet. Le code suivant met à jour les lignes chaque fois que vous enregistrez le fichier , mais si votre cas d'utilisation est différent, découvrez simplement le crochet dont vous avez besoin! (le mode org est plein de crochets)

(add-hook 'before-save-hook #'endless/update-includes)

(defun endless/update-includes (&rest ignore)
  "Update the line numbers of all #+INCLUDE:s in current buffer.
Only looks at INCLUDEs that already have a line number listed!
This function does nothing if not in org-mode, so you can safely
add it to `before-save-hook'."
  (interactive)
  (when (derived-mode-p 'org-mode)
    (save-excursion
      (goto-char (point-min))
      (while (search-forward-regexp
              "^\\s-*#\\+INCLUDE: *\"\\([^\"]+\\)\".*:lines *\"\\([-0-9]+\\)\""
              nil 'noerror)
        (let* ((file (expand-file-name (match-string-no-properties 1)))
               (lines (endless/decide-line-range file)))
          (when lines
            (replace-match lines :fixedcase :literal nil 2)))))))

Les Regexps

C'est là que vous définissez les expressions rationnelles qui seront utilisées comme première et dernière lignes à inclure. Vous pouvez donner une liste d'expressions rationnelles pour chaque extension de fichier.

(defcustom endless/extension-regexp-map 
  '(("sv" ("^class\\b" . "^endclass\\b") ("^enum\\b" . "^endenum\\b")))
  "Alist of regexps to use for each file extension.
Each item should be
    (EXTENSION (REGEXP-BEGIN . REGEXP-END) (REGEXP-BEGIN . REGEXP-END))
See `endless/decide-line-range' for more information."
  :type '(repeat (cons string (repeat (cons regexp regexp)))))

Le travailleur d'arrière-plan

C'est le gars qui fait la plupart du travail.

(defun endless/decide-line-range (file)
  "Visit FILE and decide which lines to include.
The FILE's extension is used to get a list of cons cells from
`endless/extension-regexp-map'. Each cons cell is a pair of
regexps, which determine the beginning and end of region to be
included. The first one which matches is used."
  (let ((regexps (cdr-safe (assoc (file-name-extension file)
                                  endless/extension-regexp-map)))
        it l r)
    (when regexps
      (save-match-data
        (with-temp-buffer
          (insert-file file)
          (while regexps
            (goto-char (point-min))
            (setq it (pop regexps))
            (when (search-forward-regexp (car it) nil 'noerror)
              (setq l (line-number-at-pos (match-beginning 0)))
              (when (search-forward-regexp (cdr it) nil 'noerror)
                (setq regexps nil
                      r (line-number-at-pos (match-end 0))))))
          (when r (format "%s-%s" l (+ r 1))))))))