Insérer rapidement des blocs source en mode org

61

org-mode a la capacité de rendre le code source, avec des blocs de la syntaxe suivante:

#+NAME: <name>
#+BEGIN_SRC <language> <switches> <header arguments>
    <body>
#+END_SRC

Existe-t-il une commande existante pour insérer rapidement ces blocs org-modeou dois-je utiliser un outil externe comme yasnippet?

org-mode org-babel Matthew Piziak
la source
7
Il y a plusieurs façons: (1) Modèles faciles intégrés (2) Utilisation du hydrapackage: blogpost (3) Un autre extrait pour une insertion facile du bloc source.
Kaushal Modi
Si vous collez depuis Emacs, Emacs peut remplir le mode majeur et le backlink pour vous: github.com/unhammer/org-rich-yank#org-rich-paste
unhammer

Réponses:

89

Comme @kaushalmodi le mentionne dans les commentaires, vous pouvez (org) Easy Templatesaccélérer l’insertion de différents types de blocs.

La procédure générale consiste à insérer, <suivi d'un sélecteur de modèle (généralement une seule lettre), une ligne sinon vide et à appuyer sur TAB.

Le sélecteur de gabarit pour un gabarit de bloc source générique est s, donc taper <ssuivi de TABvous donnera ceci:

#+BEGIN_SRC 

#+END_SRC

Le point sera placé à la fin de la première ligne.

C’est une bonne première approximation de ce que vous voulez réaliser, mais c’est Emacs, alors améliorons-le!

Vous pouvez définir des modèles personnalisés en ajoutant une ou plusieurs entrées à une variable appelée org-structure-template-alist. Par exemple:

(add-to-list 'org-structure-template-alist '("n" "#+NAME: ?"))

Ce code ajoute un #+NAME:modèle à org-structure-template-alist, en utilisant ncomme sélecteur de modèle. Après avoir développé ce modèle, le point sera positionné à l'emplacement de ?.

Si vous nommez toujours vos blocs de code, vous pouvez également remplacer la version d'origine du modèle de bloc source par une version étendue incluant la #+NAME:ligne:

(add-to-list 'org-structure-template-alist
             '("s" "#+NAME: ?\n#+BEGIN_SRC \n\n#+END_SRC"))

Taper <ssuivi de TABvous donnera ensuite:

#+NAME: 
#+BEGIN_SRC 

#+END_SRC

Ce n'est que la pointe de l'iceberg; vous pouvez utiliser une approche similaire pour définir des modèles supplémentaires pour des blocs de code spécifiques à une langue, des blocs de code avec des arguments d'en-tête spécifiques, etc.

itsjeyd
la source
2
Remarque: Easy Template est remplacé par une méthode incompatible dans HEAD en mode org. Je recommande d'utiliser yasnippet.
lurdan
@ lurdan est-ce toujours le cas? Je viens d'essayer <s TABEmacs 25 sur Mac OS X et cela semblait fonctionner.
Rudolf Olah
1
@RudolfOlah Oui, au moins pour HEAD en mode org (git). Même avec emacs26, le mode organisationnel intégré a toujours une org-try-structure-completionfonction (pour les modèles faciles). Quoi qu'il en soit, il sera remplacé par Structure-templates dans le futur. cf. code.orgmode.org/bzg/org-mode/commit/…
lurdan
14

Pourquoi ne pas l'écrire toi-même?

(defun org-insert-source-block (name language switches header)
  "Asks name, language, switches, header.
Inserts org-mode source code snippet"
  (interactive "sname? 
slanguage? 
sswitches? 
sheader? ")
  (insert 
   (if (string= name "")
       ""
     (concat "#+NAME: " name) )
   (format "
#+BEGIN_SRC %s %s %s

#+END_SRC" language switches header
)
   )
  (forward-line -1)
  (goto-char (line-end-position))
  )
Adobe
la source
6

Sur ma boîte 99% du temps, je crée des blocs source et 1% du temps, je fais tout le reste. Pour le 1% Easy, les modèles sont parfaits et pour le 99%, j'ai un YaSnippet.

  • Cela crée une NAMEutilisation unique org-idmais cela ne compte pas pour nous) et ensuite il me demande quelle langue je veux utiliser en la limitant à celles que j'ai dites à Org-Mode Literate Programming (babel)
  • Présente une liste de types de langues que vous avez indiqués à Mode-org que vous souhaitez utiliser et que vous pouvez choisir, au lieu de saisir tous les types (même si je ne les utilise pas tous)
  • Si la langue doit générer un fichier, elle demande le nom du fichier de sortie

Voici le YaSnippet avec mon code de support à la fin.

# -*- mode: snippet -*-
# key: sc
# name: Source Block
# group: HELP
# contributor: [email protected]
# expand-env: ((yas-indent-line 'fixed))
# --
#+NAME: ${1:`(help/org-id-new)`}
#+BEGIN_SRC ${2:$$(let ((langs (sort (-map (lambda (x) (symbol-name (car x))) (if (-contains? org-babel-load-languages '(js . t)) (-snoc org-babel-load-languages '(javascript . t)) org-babel-do-load-languages)) 'string<))) (yas-choose-value (if (-contains? langs "shell") (-snoc langs "sh") langs)))}${2:$(when (-contains? '("ditaa" "dot" "plantuml") yas-text) (concat " :file \\"./image/" (yas-field-value 1) ".png\\""))} $3
$0
#+END_SRC

Il nécessite un tiret et le mode org chargé.

(require 'org-id)
(setq org-id-link-to-org-use-id 'nil)
(setq org-id-prefix (concat "org_" (user-real-login-name) "_" (format-time-string "%Y-%m-%d") "_" (system-name)))
(setq org-id-method 'uuid)
(defun help/org-id-new ()
  "Re-purposing `org-id' hit a snag when colons were forbidden in Source-Block
  names. Adding support for a user-defined Org-Id separator would have fixed
  this but with no benefit to Org-Id. So this function removes the colon
  instead.
 "
  (interactive)
  (let* ((gend (org-id-new))
         (newid (replace-regexp-in-string ":" "_" gend)))
    newid))

Voici un exemple de vous pourrait cette fonction id:

C-u M-:
(insert (help/org-id-new))

Résulte en

org_gcr_2017-08-06_mara_DD608C9A-33B0-4A8D-9123-298746BE973Anil
Grettke
la source
2 
;;; package --- Summary
;;; Commentary:
;;; Code:
(defvar org-sai-src-default "C++"
 "This is the list used to store the default label for source code section.")

(defun org-insert-src-block ()
  "Insert the source code section in `org-mode'."
  (interactive)
  (let* ((src-code-types
          '("emacs-lisp" "python" "C" "sh" "java" "js" "clojure" "C++" "css"
            "calc" "asymptote" "dot" "gnuplot" "ledger" "lilypond" "mscgen"
            "octave" "oz" "plantuml" "R" "sass" "screen" "sql" "awk" "ditaa"
            "haskell" "latex" "lisp" "matlab" "ocaml" "org" "perl" "ruby"
            "scheme" "sqlite"))
         (src-prompt-str
          (concat "Source code type (default "
                  org-sai-src-default
                  "): "))
         (temp-src-code-types 
          (cons org-sai-src-default src-code-types))
         (src-type-str
          (completing-read src-prompt-str temp-src-code-types
                           nil nil nil nil org-sai-src-default)))
    (setq org-sai-src-default src-type-str))
    (insert (format "#+BEGIN_SRC %s\n" src-type-str))
    (newline)
    (org-indent-line)
    (insert "#+END_SRC\n")
    (forward-line -2))))

(add-hook 'org-mode-hook
          (lambda ()
            ;; keybinding for inserting code blocks
            (local-set-key (kbd "C-c s") 'org-insert-src-block)))

(provide 'orgAuxiliary)
;;; orgAuxiliary.el ends here
Yixun Bian
la source