Modifier le nom par défaut du «nouveau dossier»

Lorsque nous créons un «nouveau dossier» dans le Finder, il est automatiquement nommé «dossier sans titre».

Est-il possible de changer ce nom de dossier par défaut en nom de date actuel, par exemple "20151223"?

Avec l'aide d'AppleScript, vous pouvez accomplir cela.

Ouvrez AppleScript Editor, créez un nouveau document et collez les lignes volées suivantes:

tell application "Finder"
    try
        if exists Finder window 1 then
            set thisPath to (the target of the front window) as alias
        else
            set thisPath to (path to desktop)
        end if
    on error
        return
    end try
end tell
set x to my the_perfect_datestring()
if x is not "-ERROR" then
    set fullPath to thisPath & x as text
    tell application "Finder"
        try
            --activate
            if not (exists fullPath) then
                set y to make new folder at thisPath with properties {name:x}
            end if
            activate
            open y
        end try
    end tell
end if
on the_perfect_datestring()
    try
        set cd to (the current date)
        set the_year to year of (cd) as number
        set the_month to month of (cd) as number
        set the_day to day of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        return ((the_year & the_month & the_day) as string)
    on error
        return "-ERROR"
    end try
end the_perfect_datestring

Enregistrez le fichier en tant qu'application AppleScript (par exemple DateFolder.app) quelque part (par exemple ~ / Applications).

Ouvrez un dossier et déposez DateFolder.app sur la barre d'outils:

Pour créer un dossier dans un dossier ouvert, appuyez simplement sur l'icône de l'application dans la barre d'outils. Le nouveau dossier s'ouvrira automatiquement. Supprimez la ligne 22 du script ( open y) si vous ne voulez pas que le nouveau dossier soit ouvert. Si vous ajoutez l'application au Dock et l'ouvrez, elle créera un nouveau dossier dans le dossier le plus en avant ou sur le bureau (si aucun dossier n'est ouvert).

Testé uniquement sous Mac OS X 10.7.5. Lion!

Pour ajouter un trait d'union et l'heure actuelle, ajoutez les lignes suivantes (en remplaçant la ligne 32-34 dans le script ci-dessus):

        set the_hour to hours of (cd) as number
        set the_minute to minutes of (cd) as number
        set the_second to seconds of (cd) as number
        if the_month < 10 then set the_month to "0" & the_month
        if the_day < 10 then set the_day to "0" & the_day
        if the_hour < 10 then set the_hour to "0" & the_hour
        if the_minute < 10 then set the_minute to "0" & the_minute
        if the_second < 10 then set the_second to "0" & the_second
        return ((the_year & the_month & the_day & "-" & the_hour & the_minute & the_second) as string)