Je me demandais s'il y en avait un où je pouvais cliquer avec le bouton droit de la souris dans une instance de la fenêtre du "Finder", de sorte que j'ai l'option "Ouvrir le terminal ici". Ce serait vraiment utile.

À partir de Mac OS X Lion 10.7, Terminal fournit des services pour ouvrir une nouvelle fenêtre ou un nouvel onglet de terminal dans le dossier sélectionné dans le Finder. Ils fonctionnent également avec des noms de chemin absolus sélectionnés dans le texte (quelle que soit l'application). Vous pouvez activer ces services avec Préférences système & gt; Clavier & gt; Raccourcis clavier & gt; Prestations de service . Recherchez "Nouveau terminal dans le dossier" et "Nouvel onglet Terminal dans le dossier". Vous pouvez également leur attribuer des touches de raccourci.

En outre, vous pouvez maintenant faire glisser des dossiers (et des noms de chemin) sur l'icône de l'application Terminal pour ouvrir une nouvelle fenêtre de terminal ou sur une barre d'onglets dans une fenêtre de terminal pour créer un nouvel onglet dans cette fenêtre. Si vous faites glisser sur un onglet (plutôt que dans la vue du terminal), il exécutera une complète cd commande pour basculer vers ce répertoire sans aucune saisie supplémentaire.

À partir de OS X Mountain Lion 10.8, vous pouvez également exécuter une commande complète en faisant glisser le curseur de la souris vers un terminal. cd commander.

La solution à vos problèmes s'appelle Go2Shell et il fait exactement ce que vous décrivez. Vous pouvez le trouver sur l'App Store et le meilleur de tous ... c'est totalement gratuit.

Une approche différente: DTerm , qui vous donne une invite de commande flottante en haut de la fenêtre. Cela fonctionne dans de nombreuses applications, pas seulement dans le Finder.

cdto semble que c’est exactement ce dont vous avez besoin. C’est une mini-application, conçue pour être placée dans la barre d’outils du Finder. Lorsque vous l’exécutez, elle ouvre une fenêtre de terminal et cd dans le répertoire en cours dans le Finder.

Pour ceux qui utilisent iTerm, la syntaxe AppleScript a été modifiée dans iTerm version 3. Voici la procédure complète à suivre pour créer un raccourci dans le Finder.

1. Lancer Automator.

2. Sélectionnez "Application":

3. Choisissez "exécuter Applescript":

4. Collez le code ci-dessous:

   -- get the current directory in Finder
   on run {input, parameters}
       tell application "Finder"
           set _cwd to quoted form of (POSIX path of (folder of the front window as alias))
       end tell
       CD_to(_cwd)
   end run
   
   -- change directory in iTerm (version >= 3)
   on CD_to(_cwd)
       tell application "iTerm"
           activate
   
           try
               set _window to first window
           on error
               set _window to (create window with profile "Default")
           end try
   
           tell _window
               tell current session
                   write text "cd " & _cwd & ";clear;"
               end tell
           end tell
       end tell
   end CD_to
   

5. Cliquez sur "Fichier" - & gt; "Exporter" pour exporter en tant que .app, enregistrez-le dans /Applications.

6. Déplacez l'application dans la barre d'icônes du Finder tout en maintenant ⌘ :

Terminé !

Vous pouvez changer l'icône dans le Finder en suivant les instructions ici (changez l’icône de l’application que vous avez créée avec Automator).

J'utilise principalement cette fonction:

cf() {
  cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}

Vous pouvez également assigner un raccourci à un script comme ceux ci-dessous.

Réutilisez un onglet existant ou créez une nouvelle fenêtre (Terminal):

tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
    if (exists window 1) and not busy of window 1 then
        do script "cd " & quoted form of p in window 1
    else
        do script "cd " & quoted form of p
    end if
    activate
end tell

Réutiliser un onglet existant ou créer un nouvel onglet (Terminal):

tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
    if not (exists window 1) then reopen
    activate
    if busy of window 1 then
        tell application "System Events" to keystroke "t" using command down
    end if
    do script "cd " & quoted form of p in window 1
end tell

Toujours créer un nouvel onglet (iTerm 2):

tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
    if exists current terminal then
        current terminal
    else
        make new terminal
    end if
    tell (launch session "Default") of result to write text "cd " & quoted form of p
    activate
end tell

Les deux premiers scripts présentent quelques avantages par rapport aux services ajoutés dans 10.7:

• À partir de la version 10.9, il existe un bogue dans lequel les services recevant des dossiers en entrée ne sont jamais répertoriés dans le menu des services en mode colonne. Si vous attribuez un raccourci clavier à la fonction Nouvel onglet Terminal du service de dossiers, cela ne fonctionne pas en mode colonne.
• Ils utilisent le dossier dans la barre de titre au lieu de vous demander de sélectionner d'abord un dossier.
• Ils réutilisent l'onglet le plus en avant s'il n'est pas occupé, par exemple. exécuter une commande, afficher une page de manuel ou exécuter emacs.

Si vous utilisez 10.7 ou 10.8, changez tell application "Finder" to set p to POSIX path of (insertion location as alias) à:

tell application "Finder"
    if exists Finder window 1 then
        set p to POSIX path of (target of Finder window 1 as alias)
    else
        set p to POSIX path of (path to desktop)
    end if
end tell

Il existe un bogue dans 10.7 et 10.8 (mais pas dans 10.9 ou 10.6) dans lequel le Finder ignore les fenêtres créées après le dernier déplacement du focus dans une autre application et lors du retrait du insertion location propriété.

Vous pouvez le faire avec la fonctionnalité de service.

Le site suivant contient un exemple d'un tel service: http://blog.leenarts.net/2009/09/03/open-service-here/

Vous pouvez faire glisser n'importe quel fichier ou dossier du viseur sur une fenêtre de terminal pour insérer une chaîne du chemin absolu dudit fichier ou dossier.

Cela fonctionnera sur n’importe quelle installation standard (au moins jusqu’à 10.4 Tiger [ peut-être plus tôt? ]) sans avoir besoin de logiciel supplémentaire, nous modifions nos préférences, l’une ou l’autre pouvant faire peur à votre ami non-techy s’il s’agissait bien de son Mac sur lequel vous travaillez. Cette astuce fonctionne également pour tout processus en cours d'exécution dans le terminal, par exemple. emacs ou vi (en supposant que vous avez vi dans le mode approprié, ou de quelque manière que ce soit, les personnes qui utilisent vi le font).

Essaye ça: https://github.com/nmadhok/OpenInTerminal

Il fonctionne avec les éléments de la barre latérale du Finder, plusieurs sélections de dossiers / fichiers et tout ce que vous pouvez imaginer. Vraiment facile à utiliser!

ShellHere

http://etresoft.org/shellhere.html - Etresoft et John Daniel

… Faites un clic droit dans n'importe quelle instance d'une fenêtre "Finder" ...

Je ne sais pas s'il est possible d'y accéder via un menu contextuel, mais je garde ShellHere dans la barre d'outils du Finder .

OnMyCommand

http://free.abracode.com/cmworkshop/on_my_command.html - version 2.3 (2011-01-16)

Capture d'écran etc. à http://www.wuala.com/grahamperrin/public/2011/07/31/d/?mode=gallery

Installé et utilisé par moi sur Snow Leopard avant de passer à Lion. Il est trop tôt pour que je puisse dire si la version 2.3 est compatible avec Lion.

Vous pouvez l'application que j'ai développé FinderGo , qui est open source et facile à utiliser

Je l'utilise depuis des années http://openterminal.quentin.paris/
Faites un clic droit sur le Finder, choisissez Open Terminal

Ma version MacOS: 10.12.5 et vous n'avez pas besoin d'utiliser d'autres outils.

1. Activer les services: Préférences Système & gt; Clavier & gt; Raccourcis clavier & gt; Prestations de service

vérifier New Terminal at Folder

2. Finder & gt; Afficher & gt; Afficher la barre de chemin

3. Comment voir le service? C'est délicat.

Puisque vous pouvez voir la barre de chemin ci-dessous dans le viseur, faites un clic droit sur l’icône du fichier sur ce chemin, alors vous pouvez voir Service & gt; New Terminal at Folder

OpenTerminal Un séjour sans faille