Comment puis-je empêcher Vim d'écrire un fichier sans générer d'erreur?

J'essaie d'améliorer le code de cette réponse pour demander une confirmation avant de créer le répertoire manquant, voici ce que j'écris:

function! CreateDirectoryAskConfirmation(path)
    if !isdirectory(a:path)
        echohl Question
        echo "Create directory " . a:path . "?"
        echohl None

        let response = nr2char(getchar())
        if response ==? "y"
            call mkdir(a:path, "p")
        endif
    endif
endfunction

autocmd BufWritePre * call CreateDirectoryAskConfirmation(expand("<afile>:p:h"))

Une chose me manque: lorsque je n'appuie pas yà l'invite, j'aimerais que Vim abandonne l'écriture pour ne pas avoir l'erreur E212: Can't open file for writinget je n'ai pas besoin d' appuyer sur une autre touche pour faire disparaître le message d'erreur. Il existe un moyen d'y parvenir?

Au lieu d'utiliser l' BufWritePreautocmd, vous pouvez utiliser l' BufWriteCmd autocmd à partir de :help BufWriteCmd:

Devrait faire l'écriture du fichier et réinitialiser «modifié» en cas de succès, sauf si «+» est dans «cpo» et écrire dans un autre fichier cpo- +.

Nous pouvons simplement appeler à :writepartir de l'autocmd. Cela se chargera du réglage modified.

Ainsi, la logique serait alors modifiée pour appeler :writelorsque le répertoire existe déjà, et appeler :writeaprès avoir créé le répertoire s'il n'existe pas encore. Si vous appuyez n, nous ne faisons rien. Cela laissera le tampon tel quel et ne sera pas réinitialisé modified, donc :qvous donnera toujours une E37: No write since last changeerreur.

function! CreateDirectoryAskConfirmation(path, dir)
    silent doautocmd BufWritePre

    " Directory exists, :write and return
    if isdirectory(a:dir)
        execute 'write ' . a:path
        silent doautocmd BufWritePost
        return
    endif

    " Ask for confirmation to create this directory
    echohl Question
    echo "Create directory `" . a:dir . "' [y/N]?"
    echohl None

    let response = nr2char(getchar())
    " mkdir() and :write if we want to make a directory
    if response ==? "y"
        call mkdir(a:dir, "p")
        execute 'write ' . a:path
        silent doautocmd BufWritePost
    endif
endfunction

autocmd BufWriteCmd * call CreateDirectoryAskConfirmation(expand("<amatch>:p"), expand("<amatch>:p:h"))