Liste les types de fichiers connus

Comment puis-je obtenir une liste des noms de types de fichiers connus de vim?

Je veux pouvoir le faire de sorte que lorsque vim ne détecte pas automatiquement un type de fichier, je puisse essayer certains des types de fichiers que vim sait déjà similaires et voir s'ils fournissent une coloration syntaxique raisonnable.

Je sais que les fichiers vimscript traitant des types de fichiers sont placés dans le ftpluginrépertoire par convention, mais ils n'ont pas besoin de l'être (je ne suis pas sûr, mais je ne pense pas que les fichiers vimscript du ftpluginrépertoire sont spéciaux), alors je veux simplement demandez à vim quels types de fichiers il connaît, quelle que soit la façon dont il les a appris.

Solution simple

Tapez :setfiletype (avec un espace après) , puis appuyez sur Ctrl-d.

Voir :help cmdline-completionpour plus d'informations sur l'auto-complétion dans la ligne de commande de vim.

Solution compliquée

Cette solution utilise l' 'runtimepath'option permettant d'obtenir tous les répertoires de syntaxe disponibles, puis extrait une liste des fichiers vimscript de ces répertoires avec leurs extensions supprimées. Ce n'est peut-être pas le moyen le plus sûr de le faire, donc les améliorations sont les bienvenues:

function! GetFiletypes()
    " Get a list of all the runtime directories by taking the value of that
    " option and splitting it using a comma as the separator.
    let rtps = split(&runtimepath, ",")
    " This will be the list of filetypes that the function returns
    let filetypes = []

    " Loop through each individual item in the list of runtime paths
    for rtp in rtps
        let syntax_dir = rtp . "/syntax"
        " Check to see if there is a syntax directory in this runtimepath.
        if (isdirectory(syntax_dir))
            " Loop through each vimscript file in the syntax directory
            for syntax_file in split(glob(syntax_dir . "/*.vim"), "\n")
                " Add this file to the filetypes list with its everything
                " except its name removed.
                call add(filetypes, fnamemodify(syntax_file, ":t:r"))
            endfor
        endif
    endfor

    " This removes any duplicates and returns the resulting list.
    " NOTE: This might not be the best way to do this, suggestions are welcome.
    return uniq(sort(filetypes))
endfunction

Vous pouvez ensuite utiliser cette fonction comme vous le souhaitez, par exemple pour imprimer toutes les valeurs de la liste. Vous pouvez accomplir cela comme suit:

for f in GetFiletypes() | echo f | endfor

Notez que ceci peut probablement être un peu compacté, il en va de même pour la lisibilité. Je ne vous expliquerai pas toutes les fonctions et commandes utilisées ici, mais voici toutes les pages d'aide correspondantes:

• :help 'runtimepath'
• :help :let
• :help :let-&
• :help split()
• :help :for
• :help expr-.
• :help :if
• :help isdirectory()
• :help glob()
• :help fnamemodify()
• :help add()
• :help uniq()
• :help sort()

Si votre version de vim est suffisamment récente (v7.4.2011 +), vous pouvez demander des types de fichiers connus avec la fonction que nous pouvons maintenant utiliser pour vous aider à définir l'auto-complétion manuelle: getcompletion()

:echo getcompletion('', 'filetype')

Si vous souhaitez restreindre la liste aux types de fichiers commençant par un 'c', vous pouvez appeler

:echo getcompletion('c', 'filetype')

etc.

Remarque: contrairement aux solutions qui analysent les noms de fichier et les noms de répertoire $VIMRUNTIME/{syntax,filetype}/, cette solution est également analysée 'runtimepath'. Autant que je sache, de nouveaux types de fichiers ne sont pas définis / enregistrés à la volée avec set ft=foobar, ni après les autocommandes.

Vous pouvez également imprimer tous les types de fichiers du terminal en exécutant les 2 commandes suivantes:

1.

cd $(vim -e -T dumb --cmd 'exe "set t_cm=\<C-M>"|echo $VIMRUNTIME|quit' | tr -d '\015')

2

cat <(ls -1 ftplugin/*.vim) <(ls -1 syntax/*.vim) | tr '\n' '\0' | xargs -0 -n 1 basename | sort | uniq | cut -f 1 -d '.'

La première commande navigue simplement vers votre chemin d’exécution vim (pour moi c’était / usr / share / vim / vim80 ).

La deuxième commande répertorie tous les noms de type de fichier dans les deux dossiers où vim stocke les définitions de type de fichier.

Mise à jour

Améliorations suggérées aux deux commandes de muru qui offrent:

1.

cd $(vim -Nesc '!echo $VIMRUNTIME' -c qa)

2

find syntax ftplugin -iname '*.vim' -exec basename -s .vim {} + | sort -u

Essayez de voir dans $ VIMRUNTIME / syntax. Utilisez: echo $ VIMRUNTIME pour connaître sa valeur. Sur mon ordinateur, $ VIMRUNTIME / syntax était / usr / share / vim / vim81 / syntax. Il a tous les fichiers de syntaxe.

Si vous avez un vim avec interface graphique, vous pouvez également utiliser le menu Syntaxe pour obtenir tous les types de fichiers pris en charge.