Puis-je répéter la dernière commande d'interface utilisateur?

Je sais que je peux utiliser .pour répéter la dernière commande d'édition.

Existe-t-il un moyen de répéter la dernière commande de manipulation de l'interface utilisateur? Par exemple, je peux écrire 10<C-W>-pour réduire une fenêtre de dix lignes. Ce serait bien de pouvoir appuyer sur ⟨ une touche ⟩ de répéter facilement cette commande si je veux réduire plus.

La commande dot .fonctionne parce que Vim "garde la trace" des commandes qui modifient le contenu des tampons. Si vous exécutez :echo b:changedtick, vous le verrez incrémenter à chaque modification du tampon actuel.

Mais Vim ne "garde pas" la trace des commandes non éditables. Ainsi, non, ce que vous demandez ne peut pas être fait.

Il n'y a aucun moyen de le faire par défaut dans vim car vim ne garde pas la trace du wincmd précédemment exécuté. Cependant, il est possible de le faire grâce à des mappages intelligents:

function! s:Wincmd(count, key)
    " If count is not zero, use the original count.  If otherwise, don't
    " include a count.
    let if_count = a:count ? a:count : ""
    " This builds a wincmd from the given key, and saves it so
    " it can be repeated.
    let g:last_wincmd = "wincmd " . nr2char(a:key)
    " Execute the built wincmd
    execute if_count . g:last_wincmd
endfunction

function! s:WincmdRepeat(count)
    " If no wincmd has been executed yet, don't do anything
    if !exists('g:last_wincmd') | return | endif
    " If a count is given, repeat the last wincmd that amount of times.
    " If otherwise, just repeat once.
    let if_count = a:count ? a:count : ""
    execute if_count . g:last_wincmd
endfunction

" Overwrite the default <C-w> mapping so that the last wincmd can be kept
" track of.  The getchar function is what captures the key pressed
" directly afterwards.  The <C-u> is to remove any cmdline range that vim
" automatically inserted.
nnoremap <silent> <C-w> :<C-u>call <SID>Wincmd(v:count, getchar())<CR>

" This just calls the function which repeats the previous wincmd.  It
" does accept a count, which is the number of times it should repeat the
" previous wincmd.  You can also replace Q with whatever key you want. 
nnoremap <silent> Q :<C-u> call <SID>WincmdRepeat(v:count)<CR>

Notez que si vous avez des mappages qui les utilisent, <C-w>ils ne peuvent être répétés que s'ils ne sont pas de la norevariété. Aucun wincmds émis à l'aide de :wincmdne sera répété. De plus, aucun wincmds contenant plus d'un caractère ne peut être exécuté (tel que <C-w>gf) .

Rubriques d'aide pertinentes

• :help v:count
• :help getchar()
• :help nr2char()
• :help expr1
• :help :wincmd
• :help :execute
• :help :for
• :help :map-<silent>
• :help c_CTRL-U
• :help <SID>

Le plugin de sous- mode peut vous aider. Vous pouvez définir un "sous-mode" que vous entrez en tapant <C-W>-, dans lequel vous avez défini -(et peut-être +) de continuer à redimensionner la fenêtre.

Il existe un autre plugin appelé repmo.vim ("répéter les mouvements") qui peut faire ce que vous voulez.

Mais vous devrez spécifier les mouvements (ou actions en général) que vous souhaitez répéter. Le mien est actuellement configuré comme ceci:

let g:repmo_mapmotions = "j|k h|l zh|zl g;|g, <C-w>w|<C-w>W"
let g:repmo_mapmotions .= " <C-w>+|<C-w>- <C-w>>|<C-w><"
let g:repmo_key = ";" 
let g:repmo_revkey = "," 

Donc, après l'avoir fait, 5 CTRL-W +je peux le ;répéter autant de fois que nécessaire.

Le plugin fonctionne en créant des mappages pour chacune des clés spécifiées.

Lorsque fou tsont utilisés, les mappages ;et ,sont réinitialisés à leur comportement par défaut.

Je trouve le mappage g;particulièrement utile pour revenir à un point de montage antérieur. g; ; ; ;