Résoudre tous les alias dans une ligne de commande zsh

J'ai des alias imbriqués et je veux tous les résoudre avant d'exécuter la commande. Comment je fais ça?

S'il y a une fonction qui n'est liée à aucune touche, cela M-x foobarme convient aussi. Je pourrais même utiliser la commande externe ( type, command, which, peu importe). J'ai tout essayé depuis le fil Pourquoi ne pas utiliser "qui"? Que faut-il utiliser alors? mais rien ne fonctionne.

Notez que Ctrl-Alt-E dans bashne développe pas seulement les alias. Il développe également les variables, la substitution de commandes (!), La substitution de processus (!), L'expansion arithmétique et supprime les guillemets (il ne fait pas de génération de nom de fichier (globbing) ou d'expansion de tilde).

Il ne parvient pas toujours à étendre les alias. Donc, même s'il a ses utilisations, il est important de réaliser que son résultat change potentiellement la signification de la ligne de commande, a des effets secondaires et est potentiellement dangereux.

Par exemple dans:

$ a=';w' b=1
$ alias foo=bar
$ b=2; echo $b $a; cd /tmp/dir && for i do foo $(pwd) <(ls); done

Si j'appuie M-C-Eici, cela me donne:

$ b=2; echo 1 ;w; cd /tmp/dir && for i do foo / /dev/fd/63; done

Ce qui me donne une ligne de commande complètement différente (et imaginez ce qui se serait passé si j'avais eu rm -rf *au lieu de pwdci - dessus) et ne développe pas l' fooalias.

Avec zsh, pour s'appuyer sur la note de Gilles sur les alias développés à l'intérieur des fonctions, vous pourriez faire:

expand-aliases() {
  unset 'functions[_expand-aliases]'
  functions[_expand-aliases]=$BUFFER
  (($+functions[_expand-aliases])) &&
    BUFFER=${functions[_expand-aliases]#$'\t'} &&
    CURSOR=$#BUFFER
}

zle -N expand-aliases
bindkey '\e^E' expand-aliases

Cela ne développera les alias que si la ligne de commande actuelle est syntaxiquement valide (elle se double donc d'un vérificateur de syntaxe).

Contrairement à bashMCE, il résout également complètement les alias. Par exemple, si vous avez:

$ alias ll='ls -l'; alias ls='ls --color'
$ ll

Sera étendu à:

$ ls --color -l

Notez qu'il canonise également la syntaxe pour des choses comme:

$ for i (*) cmd $i; foo

sera changé en:

$ for i in *
        do
                cmd $i
        done
        foo

Si vous remplissez une ligne de commande dans une définition de fonction, puis imprimez la fonction, les alias seront développés. Vous obtiendrez également des espaces normalisés.

% alias foo='bar -1'
% alias bar='qux -2'
% f () foo -3
% which f
f () {
        qux -2 -1 -3
}

Pour mettre tout cela dans une commande interactive, vous pouvez créer un widget zle. Vous pouvez définir une fonction directement en insérant son code dans une entrée du functionstableau; vous obtiendrez l'effet de normalisation lorsque vous relirez.

normalize-command-line () {
  functions[__normalize_command_line_tmp]=$BUFFER
  BUFFER=${${functions[__normalize_command_line_tmp]#$'\t'}//$'\n\t'/$'\n'}
  ((CURSOR == 0 || CURSOR = #BUFFER)
  unset 'functions[__normalize_command_line_tmp]'
}
zle -N normalize-command-line
bindkey … normalize-command-line

Vous obtenez le même effet de normalisation dans le preexeccrochet . Les alias sont également développés au moment où une fonction est chargée automatiquement ( autoload -Uest couramment utilisée pour éviter l'expansion des alias).

La _expand_aliasfonction d'achèvement développe le mot sous le curseur s'il s'agit d'un alias. Il utilise le aliasestableau . Ce n'est pas récursif. Vous pouvez implémenter un expanseur d'alias plus général en utilisant aliases, mais c'est un peu difficile, car déterminer les emplacements où les alias sont développés est intimement lié à la syntaxe du shell.

Si vous avez de nombreux alias fantaisie imbriqués et que vous n'êtes pas sûr de ce que zsh fait réellement avec eux et dans quel ordre les options sont passées à la commande, vous pouvez toujours démarrer zsh avec -xoption. Cela affichera les commandes et les arguments lors de leur exécution.

Sachez cependant que cette option est plutôt destinée au débogage, elle imprime donc beaucoup de choses inutiles juste après l' zsh -xinvocation (essentiellement chaque fonction / widget / plugin de votre .zshrc), et pendant l'exécution de la commande, elle peut également être verbeuse, en particulier si vous avez défini preexecet precmdaccroché.

Je dois également mentionner qu'il imprime uniquement les commandes qui sont finalement exécutées et que les commandes séparées sont imprimées séparément, donc après

alias a='echo a'
alias b='echo b'
alias c='echo c'
alias d='echo d'
a && b || c; d

Tu verras

+zsh:1> echo a
a
+zsh:1> echo b
b
+zsh:1> echo d
d