complétion de l'onglet zsh sur une ligne vide

Je voudrais un tcsh'ism que je n'ai pas pu trouver: sur une ligne vierge sans contenu, je veux appuyer sur la touche de tabulation et voir l'équivalent d'un ls. C'est-à-dire que je veux

$ <tab>

de faire autre chose que de me donner un \ t. J'ai trouvé des ressources fantastiques pour terminer la commande, mais pas pour ce cas de base. Toute aide à ce sujet serait formidable! Merci.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Le comportement de Tabau début d'une ligne est contrôlé par le style . Cependant, il n'y a que deux comportements pris en charge:insert-tab

• achèvement comme d'habitude, sous zstyle ':completion:*' insert-tab false
• insérer un onglet, sous zstyle ':completion:*' insert-tab true
• l'un ou l'autre sous zstyle ':completion:*' insert-tab pending[=N]

Si vous souhaitez simplement terminer les commandes dans cette position, cela zstyle ':completion:*' insert-tab truesuffira. Si vous voulez quelque chose de différent, comme lister les fichiers dans le répertoire courant, vous devrez les modifier _main_complete.

Un fil récent sur la liste zsh-workers a été discuté insert-tab.

Voici l'implémentation complète de la liste automatique de tcsh dans zsh, lorsque vous appuyez sur tab sur une ligne vide

% <TAB>

C'est ici:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Si vous souhaitez émuler tcsh de plus près, ajoutez également ceci à votre .zshrc:

unsetopt always_last_prompt       # print completion suggestions above prompt

J'ai écrit ce widget zsh qui améliore l'utilisation de TAB, non seulement sur une ligne vide, mais aussi pendant que vous tapez une commande.

• Il listera les fichiers sur une ligne de commande vide et au milieu de n'importe quelle commande.
• Il répertorie les répertoires sur une ligne de commande vide.
• Il listera les exécutables sur une ligne de commande vide.

Il peut être configuré pour ajouter "cd" ou "./" dans ces cas avec une variable globale.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA