Raccourci clavier pour basculer entre les feuilles dans Excel

Réponses:

20

Ctrl+ PgUppour se déplacer vers la gauche.

Ctrl+ PgDnpour se déplacer vers la droite.

Dmatig
la source
Cela s'applique également à Excel 2013 =)
Metafaniel
et sur un macbook sans pgup et pgdown?
theonlygusti
Je souhaite qu'ils avaient un meilleur raccourci, comme Page Upet Page Downsont toujours difficiles à trouver dans les différents ordinateurs portables et pas très commodément placé sur le clavier.
Cricrazy
3

Macros VBA et raccourci clavier personnalisé pour activer la première ou la dernière feuille

Si vous souhaitez qu'un raccourci clavier réel passe à la première ou à la dernière feuille de calcul, placez ce code dans un module du classeur "PERSONNEL":

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

Accédez à l'onglet Développeur> Macros. Accédez à ces macros (ToFirstSheet et ToLastSheet). Sélectionnez-en un, cliquez sur Options et attribuez un raccourci clavier. Faites de même pour l'autre.

En l'enregistrant dans le classeur "PERSONNEL", il sera disponible dans n'importe quel fichier Excel.

Raccourcis clavier intégrés pour activer la feuille précédente ou suivante

Pour sauter une feuille de calcul vers la gauche ou la droite, vous pouvez utiliser ces raccourcis clavier par défaut:

Ctrl+PgUp

Ctrl+PgDn

Macros VBA pour activer la feuille précédente ou suivante

Voici comment accomplir la même chose en utilisant VBA, essayez ceci:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

Fonctions VBA pour retourner la feuille précédente ou suivante

Utilisez cette fonction si vous préférez obtenir l'objet de feuille de calcul précédent ou suivant:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

Utilisez les fonctions comme ceci:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub
ChrisB
la source
Comment obtenir la feuille suivante et précédente? Je veux faire un Sub ToPreviousSheetet ToNextSheet?
theonlygusti
Utilisez pour cela l'index des feuilles. Je mettrai à jour ma réponse pour l'inclure.
ChrisB
1

Vous pouvez également utiliser les touches de raccourci pour accéder à la Goboîte de dialogue. Vous pouvez ensuite taper quelque chose comme foo!A1pour naviguer vers la cellule en haut à gauche dans la feuille nommée "foo". Alors que la page précédente et la page suivante sont généralement plus rapides. Si vous avez un grand nombre (par exemple, 20+) de feuilles bien nommées, cela peut être plus rapide. Go fonctionne également bien si vous avez nommé des tableaux dans vos feuilles.

Une pression sur F5 ouvre normalement la Goboîte de dialogue.

Jeromy Anglim
la source