Comment un nombre de valeurs qui ont plus d'une occurrence dans une colonne

Dans la cellule B5, j'ai une formule:

=SUMPRODUCT((A2:A10<>"")/COUNTIF(A2:A10,A2:A10&"")-(COUNTIF(A2:A10,A2:A10&"")=1))

Si la colonne A contient les données indiquées ci-dessous, la formule renvoie la réponse correcte de 3, car trois valeurs ont plusieurs occurrences (14, 16 et 17). C'est exactement ce que je veux savoir. qu'il y a trois valeurs qui apparaissent plus d'une fois. Je n'ai pas besoin de savoir quelles sont les valeurs, ni où elles se trouvent (bien que j'aie un peu malin pour cette dernière partie).

Column A: 
12
13
14
14
14
15
16
16
17
17

Toutefois, si n'importe où dans la plage A2: A10 est une cellule vide, le nombre de valeurs en double est décrémenté de 1 (dans l'exemple ci-dessus, la formule renverrait 2, alors qu'elle devrait être 3) Dans mon exemple ci-dessous, vide la cellule est représentée par "B".

Column A:
12
13
14
B
14
15
16
16
17
17 

Dans cet exemple, 14, 16 et 17 apparaissent toujours plus d'une fois; la formule doit donc renvoyer 3, mais 2.

Je suis à peu près certain que cela est dû à la première partie =SUMPRODUCT((A2:A10<>"")où l'on compte essentiellement les cellules non vides. Bien sûr, s'il y a deux (ou plus) cellules vierges, elles sont ré-incrémentées, mais ce n'est pas vraiment correct non plus, car il y a toujours omission d'un doublon non vide (si cela a du sens).

Remarque: votre question fait référence à une plage de 9 cellules, mais vous montrez 10 valeurs dans les exemples afin que cela ne corresponde pas tout à fait ... bien que je comprenne le problème.

La première partie de votre formule est OK car c'est la méthode standard pour compter le nombre de valeurs différentes non vides ...... mais lorsque vous soustrayez la seconde, COUNTIFvous devez également exclure les blancs, vous devez donc supprimer le caractère "". part dans la seconde COUNTIF, c'est à dire cette version

=SUMPRODUCT((A2:A10<>"")/COUNTIF(A2:A10,A2:A10&"")-(COUNTIF(A2:A10,A2:A10)=1))

.... mais cette version est meilleure

=SUMPRODUCT((COUNTIF(A2:A10,A2:A10)>1)/COUNTIF(A2:A10,A2:A10&""))

Les deux formules fonctionneront pour les données textuelles ou numériques dans A2: A10 (ou un mélange des deux), mais pour les valeurs numériques uniquement (selon votre exemple), vous pouvez également utiliser une FREQUENCYfonction comme celle-ci.

=SUMPRODUCT((FREQUENCY(A2:A10,A2:A10)>1)+0)