Utilisation de find () dans Excel pour supprimer du texte de la chaîne

10

J'utilise find pour supprimer une partie de la chaîne de test dans la valeur de la cellule de recherche

Par exemple, je recherche ce qui suit dans la cellule A2 Application: sales_rep_supportet j'utilise find =RIGHT(a2,FIND(" ",a2)+4)pour le changer sales_rep_support.

Cependant, je rencontre des problèmes parce que j'ai d'autres valeurs qui doivent être analysées, telles que

Application: EComm_sk
Application: PG_Prescreen
Application: sales_rep_support
Application: Retention_sk

etc....

Ce que j'ai essayé d'accomplir, c'est de supprimer simplement Application:le début de la chaîne

J'ai également essayé sans left()succès.

microsoft-excel worksheet-function Tom Cole
la source

Réponses:

12

Utilisez SUBSTITUTE.

=SUBSTITUTE(A2,"Application: ","")
Excellll
la source
3

En fait, je pense que le moyen le plus simple est d'utiliser la fonction Rechercher et remplacer sur la colonne concernée si vous avez l'intention de supprimer l'original ultérieurement.

  1. Appuyez sur Ctrl+ H.

  2. Rechercher Application:("Application", deux points, espace) Remplacer par rien

  3. Dans la fenêtre Rechercher et remplacer, cliquez sur Options >>et assurez-vous que «Dans:» est réglé sur «Feuille» et que «Faire correspondre le contenu de la cellule entière» n'est pas coché.

Sinon, une autre fonction que SUBSTITUTE()vous pouvez utiliser est MID():

=MID(text, start, length)

Dans votre cas, vous pouvez utiliser:

=MID(A2, 14, LEN(A2))

Ce qui prendra tout de la position de caractère 14 (après tous les caractères de "Application:") à la fin du texte. LEN(A2)est en fait plus grand que le texte que vous voulez, mais cela n'a pas d'importance, cela signifie que cela prendra tout jusqu'à la fin.

Jerry
la source
1

Pourquoi ne pas simplement utiliser =REPLACE(A2,1,12,"")ceci remplace les caractères 1-12 par "" (rien) et affiche donc simplement la recherche (A2)du 13ème caractère, supprimant "Application:"

Josh Baker
la source
-1 
=TRIM(RIGHT(A2,LEN(A2)-FIND(":",A2,1)))
Moshood Adefuye
la source
Il pourrait être amélioré en ajoutant une fonction TRIM à la réponse comme ci-dessus. J'espère que vous le trouverez utile.
Moshood Adefuye
1
C'est vraiment un commentaire et non une réponse à la question d'origine. Vous pouvez toujours commenter vos propres articles, et une fois que vous aurez une réputation suffisante, vous pourrez commenter n'importe quel article . Veuillez lire Pourquoi ai-je besoin de 50 points de réputation pour commenter? Que puis-je faire à la place?
DavidPostill
-3

Pourquoi diable pensez-vous que =RIGHT(A2,FIND(" ",A2)+4) c'est une façon raisonnable d'appeler RIGHT()? D'où 4vient-il? Qu'est-ce que cela signifie?

L'utilisation de RIGHTest

DROITE ( texte , [ num_chars ])

c'est-à-dire que le deuxième paramètre est le nombre de caractères que vous souhaitez extraire.

Pendant ce temps, FIND(" ", A2)est la position du premier espace A2, qui est toujours 13 tant que les 12 premiers caractères sont Application:et le 13ème est un espace. Il en FIND(" ",A2)+4est toujours de 17; vous obtenez toujours les 17 caractères les plus à droite.

Pour tout récupérer après Application: , utilisez

=RIGHT(A2, LEN(A2)-FIND(" ", A2))

ou simplement

=RIGHT(A2, LEN(A2)-13)
G-Man dit «Réintègre Monica»
la source