Comment renommer des fichiers en fonction de l'horodatage, avec un script batch?

Supposons que 10 fichiers sont générés chaque jour par le système sous D: \ Temp. Les noms sont générés aléatoirement.

Supposons que je dois renommer le plus ancien en 'aaa', le deuxième en 'bbb', puis 'ccc', 'ddd', etc.

supposons que ce sont les noms de cible que je vais utiliser:

Beijing
shanghai
hangzhou
suzhou
newyork
lanzhou
huzhou
guangzhou
tianjin
sichuang

Quelqu'un peut-il aider avec un script batch pour accomplir cela?

En fait, j’ai posé cette question hier et j’ai reçu une réponse merveilleuse avec PowerShell, mais aujourd’hui, je remarque que la machine virtuelle de la société ne me permet pas d’installer PowerShell (il n’est pas autorisé à l’installer par vous-même). peuvent conserver leurs (accepter) votes.

@echo off
setlocal disableDelayedExpansion
set "file1=aaa"
set "file2=bbb"
set "file3=ccc"
set "file4=ddd"
set "file5=eee"
set "file6=fff"
set "file7=ggg"
set "file8=hhh"
set "file9=iii"
set "file10=jjj"

for /f "tokens=1,2* delims=: " %%A in (
  'wmic datafile where "drive='d:' and path='\\temp\\'" get creationDate^, name ^| findstr "^[0-9]" ^| sort ^| findstr /n "^"'
) do for /f "delims=" %%F in ("%%C") do (
  setlocal enableDelayedExpansion
  for %%N in ("!file%%A!") do (
    endlocal
    ren "%%F" %%N
  )
)

Si vous voulez changer le chemin, vous devez être sûr de doubler tout \comme \\et assurez - vous que le chemin commence et se termine par \\. La lettre de lecteur appropriée (avec deux points) doit figurer dans l'option de lecteur.

Les valeurs de lecteur et de chemin doivent être entre guillemets simples - WMIC utilise la syntaxe SQL.

Cela devrait fonctionner pour vous. Il renomme 26 fichiers aaaà zzz, date de création la plus ancienne. Regardez la sortie et supprimez la echocommande, si elle est OK.

@echo off&setlocal
set "startfolder=D:\temp"
set "alphas=abcdefghijklmnopqrstuvwxyz"
cd /d "%startfolder%"

set /a counter=0
for /f "tokens=3*" %%a in ('dir /a-d /od /tc ^| findstr "^[0-9]"') do set "fname=%%b"&call:process
goto:eof

:process    
setlocal enabledelayedexpansion
set "nname=!alphas:~%counter%,1!!alphas:~%counter%,1!!alphas:~%counter%,1!"
if not defined nname goto:eof
echo rename "%fname%" "!nname!"
endlocal
set /a counter+=1
goto:eof

Si votre dircommande indique l'heure avec AM / PM, réglez tokens=4*.