ZSH: sélection automatique du menu pour la recherche dans l'historique

ZSH dispose d’un menu puissant, par exemple la complétion automatique. pour choisir un répertoire, choisir un processus avec kill (kill [tab] [tab]). Vous pouvez utiliser les flèches pour naviguer parmi les choix.

Est-il possible d'avoir également le menu contextuel pour la recherche dans l'historique (CTRL + R)? De manière à ce que le menu permette de naviguer dans les correspondances de la barre de recherche actuelle de CTRL + R?

zsh-navigation-tools fait quelque chose comme ça. Si vous utilisez oh-my-zsh, il vous suffit d'ajouter zsh-navigation-tools à plugins=(...) dans ton .zshrc alors ctrl-R vous donnera un historique de défilement avec haut / bas et recherche / filtrage. Vous pouvez l'utiliser sans oh-my-zsh mais la configuration semble être plus de travail.

1. Pas que je sache de.

2. Peut-être tu veux essayer predict-on, qui fait quelque chose en rapport avec ce que vous demandez:

   autoload -U predict-on
   zle -N predict-on
   zle -N predict-off
   bindkey '^X1' predict-on
   bindkey '^X2' predict-off
   

C'est possible; en principe, j'ai modifié le _kill achèvement de travailler aussi pour les événements de l'histoire.

Voici un exemple. après avoir sélectionné une entrée, vous appuyez une fois sur [ENTER] pour accepter le numéro d'événement (la ligne de commande lit alors f. e. hc 780 ) et appuyez à nouveau sur [ENTER] pour exécuter la commande. (Utilisation fc au lieu de hc si vous souhaitez modifier la ligne de commande avant son exécution).

$ hc Makefile[TAB]
history event
 1906  9.3.2013 18:10  vi Makefile
 1867  9.3.2013 17:26  less Makefile
  780  3.2.2013 17:54  cat Makefile                
  776  3.2.2013 17:51  cat ../Makefile     

Pour l'utiliser, placez les fichiers ajoutés dans un répertoire de votre $fpath et ajoutez ces lignes dans votre ~/.zshrc:

zstyle ':completion:*:historyevent' command 'fc -dE -lr 1'
zstyle ':completion:*:historyevent' sort no

Enfin, commencez une nouvelle zsh session.

Attention, c'est une solution rapide et sale, mais elle a bien fonctionné pendant un certain temps maintenant.

_histoireevent

#autoload

local out histevent list expl match desc listargs all nm ret=1

_tags historyevent || return 1

all=(-U)
match="*[[:blank:]]*[[/[:blank:]]$PREFIX*$SUFFIX*"
nm="$compstate[nmatches]"

out=( "${(@f)$(_call_program historyevent fc -l 2>/dev/null)}" )
desc="$out[1]"
out=( "${(@M)out[2,-1]:#${~match}}" )

histevent=( "${(@)${(@M)out##[^0-9]#[0-9]#}##*[[:blank:]]}" )

if zstyle -T ":completion:${curcontext}:historyevent" verbose; then
  list=( "${(@Mr:COLUMNS-1:)out}" )
  desc=(-ld list)
else
  desc=()
fi

_wanted processes expl 'history event' \
    compadd "$@" "$desc[@]" "$all[@]" -a - histevent && ret=0

if [[ -n "$all" ]]; then
  zstyle -s ":completion:${curcontext}:historyevent" insert-ids out || out=menu

  case "$out" in
  menu)   compstate[insert]=menu ;;
  single) [[ $compstate[nmatches] -ne nm+1 ]] && compstate[insert]= ;;
  *)      [[ ${#:-$PREFIX$SUFFIX} -gt ${#compstate[unambiguous]} ]] &&
              compstate[insert]=menu ;;
  esac
fi

return ret

_fc

#compdef fc

local curcontext="$curcontext" line state ret=1

_arguments -C \
   '-e[editor command]' \
   '-l[list last history events]' \
   '-n[suppress numbers]' \
   '-r[reverse order]' \
   '*:history event:->historyevent' && ret=0

if [[ -n "$state" ]]; then
  _alternative \
    'historyevent:: _historyevent' && ret=0
fi

return ret