Comment forcer Windows à rechercher des mises à jour?

Après une nouvelle installation de Windows - XP ou 7 - comment "forcer" les mises à jour Windows?

Je ne veux pas avoir de "vieilles" mises à jour Windows après une semaine, donc cela pourrait-il être fait en "une seule étape"? Existe-t-il des commandes "magiques" qui forcent Windows à rechercher les mises à jour et, le cas échéant, à les installer?

Vous pouvez rechercher et installer des mises à jour automatiquement à l'aide d'un script. Cela fonctionnera sous XP ou Windows 7.

Il existe un certain nombre de scripts disponibles en téléchargement, voici le mien :

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain.  It may be freely
' used, modified, and distributed.  However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
'   0 = scripting failure
'   1 = error obtaining or installing updates
'   2 = installation successful, no further updates to install
'   3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete.  Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop 

Vous exécutez cela à partir de la ligne de commande comme ceci:

cscript wsusupdate.vbs

Mon script n'est que peu fonctionnel mais peut toujours être utile. Il existe d'autres scripts de ce type avec de nombreuses fonctionnalités supplémentaires, essayez une recherche Google.

Au-delà de la manière habituelle d'utiliser Windows Update, vous pouvez forcer une vérification à partir d'une ligne de commande.

Ouvrez une invite de commande administrateur et exécutez:

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exe est le client AutoUpdate de Windows Update et est utilisé pour vérifier les mises à jour disponibles (pour les différentes versions de la plate-forme MS Windows) à partir de Microsoft Update.

Cela ne forcera pas une installation.

Pour vérifier les mises à jour, accédez au Panneau de configuration, Sécurité, Windows Update, puis cliquez sur "Rechercher les mises à jour".

Une autre façon de forcer une véritable nouvelle analyse des mises à jour consiste à nettoyer l'ardoise, en supprimant toutes les mises à jour stockées dans % windir% \ Windows \ SoftwareDistribution \ Download :

    NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

Ensuite, allez dans Windows Update et "Rechercher les mises à jour". Cela peut prendre une heure, car chaque fichier pouvant être mis à jour sur votre volume système est vérifié (les "Vérifications des mises à jour" suivantes seront rapides). Cette approche élimine les erreurs, les mises à jour bâclées et donne un système propre et à jour, du moins dans la mesure où MS le voit.

j'utilise un outil tiers appelé wuinstall pour mettre à jour l'installation de nouvelles fenêtres. avec cela, vous pouvez automatiser l'ensemble du processus de mise à jour, y compris les redémarrages automatiques. Je pense que c'est l'un des moyens les plus rapides d'obtenir une nouvelle fenêtre à jour sans la présence des utilisateurs.

J'ai constaté que si, dans le cadre de votre nouvelle installation sur Windows 7, vous avez mis à niveau IE ou que vous n'avez pas encore exécuté IE et répondu aux questions d'introduction, Windows Update vous donnera une erreur. Je n'ai pas non plus trouvé de moyen de passer de Windows Update à Microsoft Update sans passer par l'interface graphique, donc je lance manuellement IE, le fais initialiser puis je configure Windows Update via l'interface graphique, afin que je puisse passer à Microsoft Update et éviter le erreur initiale. Votre kilométrage peut varier.

J'ai réussi à suivre les étapes de ce message , en installant IE8 et WI4.5 , cela déclenchera des mises à jour automatiques pour démarrer les téléchargements.