Comment additionner une plage de cellules avec des valeurs N / A?

11

J'ai une plage et je dois la résumer à l'aide de la fonction SUM, mais le résultat est N / A s'il existe une valeur N / A. Comment puis-je faire la fonction SUM pour traiter la valeur N / A comme une valeur 0? Aidez-moi!

microsoft-excel-2010 Nam G VU
la source

Réponses:

16

Utiliser la formule matricielle

=SUM(IF(ISNA(A1:A4),0,A1:A4))

Appuyez sur Ctrl+ Shift+ Enteraprès avoir entré la formule

Remarque: remplacez A1:A4par votre cuisinière

Wilson
la source
1
+1: Une belle amélioration de ma solution - pas besoin de modifier les données d'origine.
Mike Fitzpatrick
1
Agréable. Je n'ai jamais pensé à utiliser une formule matricielle. J'étais content d'utiliser = SUMIF (A1: A4, "<> # N / A") jusqu'à ce que je découvre qu'il se casse si la feuille de calcul est ouverte dans une copie d'Excel localisée pour une autre langue! Malheureusement, remplacer "<> # N / A" par "ISNA ()" ne fonctionne pas, mais la formule matricielle est une belle solution multilingue. Malheureusement, ce n'est pas une approche appropriée pour le même défi avec AVERAGEIF ()… :-(
Joe Carroll
@JoeCarroll, vous pouvez utiliser=AVERAGE(IF(ISNA(A1:A4),"",A1:A4))
wilson
Merci @wilson! Quand je l'ai considéré brièvement, je n'ai pas pensé à utiliser "" au lieu de zéro, idiot :-) L'utilisation de zéro affecte la taille de l'échantillon, bien sûr, ce qui m'a conduit à rejeter la solution, mais les cellules vides sont tout simplement ignorées.
Joe Carroll
Ne fonctionne pas avec le magique Cr @ pXcel 2013, mais la réponse ci-dessous (= agrégat) fonctionne comme un charme!
5

La manière la plus simple:

Utilisez SUMIFla valeur> 0.

Ainsi, la syntaxe de celui-ci est

=SUMIF(A1:B2, "> 0")

Vous obtiendrez le même résultat car il ignorera toutes les valeurs non numériques ou 0.

JNK
la source
2
Votre suggestion ne fonctionnera pas avec des nombres négatifs. Merci quand même.
Nam G VU
1
Pourrait =SUMIF(A1:B2, ">=0") + SUMIF(A1:B2, "<0")inclure des nombres négatifs. Je soupçonne que ce serait plus rapide que la solution de formule de tableau acceptée, si les performances sont un problème.
kizzx2
3

Il existe une nouvelle fonction dans Excel qui ajoutera toutes les valeurs positives ou négatives tout en ignorant les NA. 

=aggregate(9,6, range of your data)

9 est utilisé pour la somme tandis que 6 est pour ignorer toutes les NA. Il existe également d'autres options, à côté de l'ajout. Par exemple, vous pouvez faire un produit, un écart-type, etc.

Plus d'informations sur AGGREGATE ici .

Muhammad Wajid Raza
la source
solution élégante pour excel 2010 et suivants :)
wilson
0

Utilisez SUBTOTAL à la place:

=SUBTOTAL(9,A1:A50)
une variante
la source
Je suis en train , sumtotalmais j'ai le même problème qu'avecsum
fguillen
0

Vous pouvez convertir le # N / A en zéros dans votre plage source, puis utiliser la fonction SUM normale:

= IF (ISNA (OriginalFormula), 0, OriginalFormula)
Mike Fitzpatrick
la source
2
Depuis Office 2007, il y a une nouvelle fonctionnalité, IFERRORet elle peut ressembler à ceci: la =IFERROR(OriginalFormula,0)rendre beaucoup plus agréable.
Michael
@agentmike, d'accord, je l'utilise fréquemment ces jours-ci.
Mike Fitzpatrick
0

S'il y a des formules que je copierais sous forme de nombres, remplacer # N / A dans la colonne par 0, puis additionner comme d'habitude

cynthia
la source
-1

De cette façon, cela semble fonctionner: 

SUMIF(range;"<>#N/A";range)

Pas si robuste mais efficace!

Bruno
la source