Comment échanger une colonne et une ligne dans une table (Transposer) dans iWork Numbers?

8

Je veux transposer une table (échanger des lignes en colonnes et vice versa). Comment faire cela dans iWork Numbers.

mac iwork iwork-numbers Saneef
la source

Réponses:

4

J'ai écrit un simple AppleScript qui le fait.

tell application "Numbers"
    activate
    tell the front document
        tell the first sheet
            set original_range to selection range of first table

            set orignal_table to first table
            set number_of_columns to column count of orignal_table
            set number_of_rows to row count of orignal_table
            set trasposed_table to make new table with properties {row count:number_of_columns, column count:number_of_rows}

            repeat with i from 1 to number_of_columns
                repeat with j from 1 to number_of_rows
                    tell orignal_table
                        set original_value to the value of cell i of row j
                    end tell
                    tell trasposed_table
                        set the value of cell j of row i to original_value
                    end tell
                end repeat
            end repeat

        end tell
    end tell
end tell

Ici vous trouverez plus de détails à ce sujet.

mariosangiorgio
la source
2
Il convient de mentionner que cette formule prend le valuesens des cellules: si vous avez des formules dans les cellules que vous transposez, seule leur sortie sera transposée. Les formules ne le seront pas.
Nick Q.19
3

Ceux qui utilisent la dernière version de Numbers peuvent utiliser l'option "Transposer les lignes et les colonnes" dans le menu "Tableau", comme on le voit dans cette réponse sur StackExchange . L'image ci-dessous a également été «empruntée» sans vergogne à cette réponse, pour une référence facile.

Cendre
la source