Comment puis-je échapper à un certain caractère dans une variable dans un fichier de commandes

J'ai fait ce script mais ça ne marche pas:

for /R %%f in (*.mkv) do (
 ffmpeg -i "%%f" -vf subtitles="%%~nf.mkv" -acodec copy "%%~nf.mp4"
 )

 PAUSE

Après avoir recherché le problème, j'ai constaté que le problème est le nom du fichier. Les crochets doivent être masqués (par exemple, [1080p]coolvid.mp4devrait devenir \[1080p\]coolvid.mp4. Comment puis-je faire cela avec le nom du fichier (%% f)?

Les crochets doivent être échappés

Utilisez le fichier de commandes suivant:

@echo off
setlocal
setlocal enabledelayedexpansion
for /r %%f in (*.mkv) do (
  set _a=%%~nf
  set _b=!_a:[=\[!
  set _name=!_b:]=\]!
  set _c=%%f
  set _d=!_c:[=\[!
  set _fullname=!_d:]=\]!
  ffmpeg -i "!_fullname!" -vf subtitles="!_name!.mkv" -acodec copy "!_name!.mp4"
  )
endlocal
pause

Lectures complémentaires

• Index AZ de la ligne de commande Windows CMD - Une excellente référence pour tout ce qui concerne la ligne de commande cmd de Windows.
• enabledelayedexpansion - L'extension retardée entraîne l'extension des variables au moment de l'exécution plutôt qu'au moment de l'analyse.
• for / r - Boucle dans les fichiers (sous-dossiers Recurse).
• set - Affiche, définit ou supprime les variables d'environnement CMD. Les modifications effectuées avec SET ne resteront que pour la durée de la session CMD en cours.
• variable edit / replace - Modifie et remplace les caractères attribués à une variable chaîne.
• FFmpeg Documentation: Citation et échappement - Détails citant et échappant spécifique à ffmpeg.

EDIT: le code original échouera si vous exécutez un fichier (ou un chemin de fichier) contenant le !caractère, car l’expansion différée est activée et que la variable FOR est développée avant l’expansion retardée. Donc, les noms avec !seront corrompus.

Il est facile de remédier à ce problème en activant ou désactivant le développement retardé dans la boucle, de sorte qu'aucune variable FOR ne soit développée tant que le développement retardé est activé.

@echo off
setlocal disableDelayedExpansion
for /r %%f in (*.mkv) do (
  set _a=%%~nf
  set _c=%%f
  setlocal enableDelayedExpansion
  set _b=!_a:[=\[!
  set _name=!_b:]=\]!
  set _d=!_c:[=\[!
  set _fullname=!_d:]=\]!
  ffmpeg -i "!_fullname!" -vf subtitles="!_name!.mkv" -acodec copy "!_name!.mp4"
  endlocal
)
endlocal
pause