Comment éditer la complétion de commande pour ssh sur zsh?

Je voudrais configurer la complétion de commande sur zsh pour afficher les noms d'hôtes après avoir tapé

ssh [TAB]

prendre les noms de mon fichier .ssh / config (et de préférence à partir des hôtes connus et / etc / hosts et partout ailleurs qui a du sens) et présenter une seule liste.

Il fait une partie de cela actuellement, mais

1. il n'utilise pas du tout .ssh / config
2. il nécessite d'abord un nom d'utilisateur, même si l'utilisation de .ssh / config rend la saisie des noms d'utilisateur inutile
3. il présente plusieurs listes (probablement une de known_hosts et une autre de / etc / hosts, mais je ne l'ai pas vérifié)

Je veux donc inclure les noms d'utilisateurs connus ainsi que les noms d'hôtes connus dans la liste (de préférence unique) après avoir tapé ssh [TAB]

(Je viens ici avant Google parce que 1) cela entraînera le stockage de la réponse ici, et 2) c'est probablement plus efficace. Si personne d'autre ne répond, je traquerai la réponse.)

Voici la partie pertinente de mon .zshrc. Il n'a pas changé depuis 2002, donc je pourrais l'écrire différemment aujourd'hui, mais il fonctionne toujours pour compléter les noms d'hôte de ~/.ssh/configet ~/.ssh/known_hosts(s'il HashKnownHostsest désactivé - il n'existait pas à l'époque).

h=()
if [[ -r ~/.ssh/config ]]; then
  h=($h ${${${(@M)${(f)"$(cat ~/.ssh/config)"}:#Host *}#Host }:#*[*?]*})
fi
if [[ -r ~/.ssh/known_hosts ]]; then
  h=($h ${${${(f)"$(cat ~/.ssh/known_hosts{,2} || true)"}%%\ *}%%,*}) 2>/dev/null
fi
if [[ $#h -gt 0 ]]; then
  zstyle ':completion:*:ssh:*' hosts $h
  zstyle ':completion:*:slogin:*' hosts $h
fi

La fonction qui fournit l' sshachèvement se trouve /usr/share/zsh/functions/Completion/Unix/_sshsur mon système.

Voir aussi la man zshcompsysdocumentation (surtout faire une recherche sur "host" qui apparaît à plusieurs endroits et "ssh" qui apparaît à quelques endroits).

Il est possible que l'ajout d'une zstylecommande à votre ~/.zshrcfonction fasse ce que vous recherchez sans avoir à modifier la fonction d'achèvement.

Je fais cela en utilisant une liste de tous les hôtes sur un domaine donné en utilisant dig. Vous pouvez remplacer la fonction ci-dessous par le système de recherche que vous souhaitez, y compris votre fichier d'hôtes ou une liste statique:

function complete_host_from_zone () {
    reply=(`dig axfr ouraynet.com @ns1.ouraynet.com | grep -e '^[a-z]' | cut -d\. -f1`)
}
compctl -x 'p[1]' -K complete_host_from_zone -- ssh

Remarque: Le code ci-dessus peut ne pas remplacer complètement le système complet de la commande ssh dans votre configuration. Si vous avez des problèmes, essayez de changer la commande "ssh" en une autre commande aléatoire comme "mycompletetest" et voyez si la complétion fonctionne pour cela.

Notez également que cela effectue le transfert de la zone DNS à chaque achèvement! Si vous l'utilisez beaucoup ou sur un domaine assez statique, il serait judicieux de faire la recherche et d'enregistrer le résultat, puis dans votre fonction de recherche, définissez simplement reply = zone_result.

J'aime garder mon known_hostsfichier haché et préfère ne pas l' HashKnownHostséteindre. J'avais trouvé que semer ce que @Gilles a avec ce qui est déjà dans mon histoire a été assez efficace pour mes besoins.

h=($(echo $(history | awk '{print $4 " " $5 "\n"}' | grep 'ssh ' | awk '{print $2}' | sort -u)))
if [[ -r ~/.ssh/config ]]; then
  h=($h ${${${(@M)${(f)"$(cat ~/.ssh/config)"}:#Host *}#Host }:#*[*?]*})
fi
if [[ -r ~/.ssh/known_hosts ]]; then
   h=($h ${${${(f)"$(cat ~/.ssh/known_hosts{,2} || true)"}%%\ *}%%,*}) 2>/dev/null
fi
if [[ $#h -gt 0 ]]; then
  zstyle ':completion:*:ssh:*' hosts $h
  zstyle ':completion:*:slogin:*' hosts $h
fi

Aussi, FWIW, c'est ce que j'ai utilisé pour Bash:

# SSH Autocompletion
complete -W "
  $(echo $(grep '^\s*ssh ' ~/.bash_history | sort -u | sed 's/^ssh //' | awk '{print $1}'))
  $(echo $(history | awk '{print $2 " " $3}' | grep 'ssh ' | awk '{print $2}' | sort -u))
  $(sed 's/#.*//;' ~/.ssh/config | awk ' /^Host (.+)$/ {$1 = "";print tolower($0)}')
" ssh