Activation silencieuse d'Office 2010 après une installation sans assistance

J'ai créé une installation sans assistance d'Office 2010 à l'aide de l'OPO. Nous utilisons un MAK plutôt qu'un KMS (pas ma décision). Existe-t-il un moyen d'activer Office 2010 après l'installation? Même si la clé est définie lors de l'installation, elle ne s'active pas.

Je ne veux pas que les utilisateurs soient invités à s'activer car cela va être dans un environnement de laboratoire.

Au cas où quelqu'un se demanderait - Office installe OSPP.VBS dans le répertoire office14 et peut gérer l'activation de bureau, entre autres.

Dans l'OPO, je l'ai configuré pour s'exécuter c:\windows\system32\cscript C:\"Program Files (x86)\Microsoft Office\Office14\OSPP.VBS" /actpendant la post-installation.

Tous les produits de bureau sont activés après cela. Je l'ai installé silencieusement Visio, Project puis Office et ai Office lancer l'activation après et les trois produits sont activés en même temps.

Pas pour brouiller les eaux sur ce post, mais je l'ai configuré à l'aide de cette commande dans OCT:
[WindowsFolder] \ system32 \ cscript [INSTALLLOCATION] \ OSPP.VBS
Avec le paramètre de / act

Juste au cas où quelqu'un d'autre aurait besoin de ces informations. Ross

Jetez simplement ce lot dans votre script post sysprep, devrait faire l'affaire pour vous. Testé sur des systèmes 32 bits et 64 bits ainsi que sur différents systèmes d'exploitation.

Peut-être que quelqu'un peut vbs celui-ci ou autre chose.

activateproper.cmd

REM CUSTOMER NAME HERE
REM DATE LAST MODIFIED

set _win7vlk=XXXXX-8FFQX-YYYYY-33XHT-ZZZZZ
set _2010vlk=YYYYY-YYYYY-WQGB6-KW8P8-XXXXX

REM Use current working dir
cd /d "%~dp0"

if not defined _win7vlk if not defined _2010vlk goto :nokey

echo Checking for internet connectivity needed to activate
echo This screen will not progress until internet is established
echo If you are using firewall please disable the firewall temporarily

:LOOP
PING -n 3 google.com|find "TTL" >NUL
IF NOT ERRORLEVEL 1 goto :ENDLOOP
IF     ERRORLEVEL 1 goto :LOOP
:ENDLOOP
echo Internet Detected

echo Change the time
net time \\LANMACHINEWITHCORRECTTIME /set /y

echo Prompt to activate Windows 7 if needed
if exist "%windir%\system32\slmgr.vbs" FOR /F "tokens=5" %%a in ('cscript "%windir%\system32\slmgr.vbs" -xpr') do (set _act=%%a)
if "%_act%" neq "activated." if defined _win7vlk (
    cscript "%windir%\system32\slmgr.vbs" -ipk %_win7vlk%
    cscript "%windir%\system32\slmgr.vbs" -ato
    )

echo Prompt to activate Office 2010 if needed
if exist "%PROGRAMFILES%\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES%
if exist "%PROGRAMFILES% (x86)\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES% (x86)

if defined _offver if defined _2010vlk (FOR /F "tokens=3* delims=: " %%a in ('cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /dstatus') do (
    if "%%a" == "---OOB_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---OOT_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---NOTIFICATIONS---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    ))



:nokey

Vous pouvez également activer Office 2010 au moment où vous installez une clé MAK en définissant la valeur de la propriété AUTO_ACTIVATE. Pour ce faire, procédez comme suit :

1. Dans l'OPO, sélectionnez Modifier les propriétés de configuration dans le volet gauche, puis cliquez sur Ajouter dans le volet droit.

2. Dans la boîte de dialogue Ajouter une valeur de propriété , dans la zone Nom , tapez AUTO_ACTIVATE . Notez que les noms de propriété doivent être en majuscules.

3. Dans la zone Valeur , tapez 1 , puis cliquez sur OK .