CMake: affiche toutes les variables accessibles dans un script

Je me demande s'il existe un moyen d'imprimer toutes les variables accessibles dans CMake. Je ne suis pas intéressé par les variables CMake - comme dans l' --help-variablesoption. Je parle de mes variables que j'ai définies, ou des variables définies par les scripts inclus.

J'inclus actuellement:

INCLUDE (${CMAKE_ROOT}/Modules/CMakeBackwardCompatibilityCXX.cmake)

Et j'espérais que je pourrais simplement imprimer toutes les variables qui sont ici, au lieu d'avoir à parcourir tous les fichiers et lire ce qui était disponible - Je peux trouver certaines variables que je ne connaissais pas qui pourraient être utiles. Il serait bon de faciliter l'apprentissage et la découverte. C'est strictement pour le débogage / développement.

Ceci est similaire à la question dans Imprimer toutes les variables locales accessibles à la portée actuelle dans Lua , mais pour CMake!

Quelqu'un a-t-il fait cela?

En utilisant la get_cmake_propertyfonction, la boucle suivante imprimera toutes les variables CMake définies et leurs valeurs:

get_cmake_property(_variableNames VARIABLES)
list (SORT _variableNames)
foreach (_variableName ${_variableNames})
    message(STATUS "${_variableName}=${${_variableName}}")
endforeach()

Cela peut également être intégré dans une fonction de commodité qui peut éventuellement utiliser une expression régulière pour imprimer uniquement un sous-ensemble de variables avec des noms correspondants

function(dump_cmake_variables)
    get_cmake_property(_variableNames VARIABLES)
    list (SORT _variableNames)
    foreach (_variableName ${_variableNames})
        if (ARGV0)
            unset(MATCHED)
            string(REGEX MATCH ${ARGV0} MATCHED ${_variableName})
            if (NOT MATCHED)
                continue()
            endif()
        endif()
        message(STATUS "${_variableName}=${${_variableName}}")
    endforeach()
endfunction()

Pour imprimer des variables d'environnement, utilisez le mode de commande de CMake :

execute_process(COMMAND "${CMAKE_COMMAND}" "-E" "environment")

Une autre façon consiste à simplement utiliser:

cmake -LAH

Depuis la page de manuel :

-L[A][H]

Répertorie les variables mises en cache non avancées.

Lister les variables de cache exécutera CMake et listera toutes les variables du cache CMake qui ne sont pas marquées comme INTERNALou ADVANCED. Cela affichera efficacement les paramètres actuels de CMake [...].

Si Aest spécifié, il affichera également des variables avancées.

Si Hest spécifié, il affichera également l'aide pour chaque variable.

ccmakeest une bonne option interactive pour inspecter de manière interactive les variables mises en cache ( option(ou set( CACHE:

sudo apt-get install cmake-curses-gui
mkdir build
cd build
cmake ..
ccmake ..