Remplacer globalement la liaison de clé dans Emacs

Comment puis-je définir une liaison de clé qui remplace globalement et a priorité sur toutes les autres liaisons pour cette clé? Je veux remplacer toutes les cartes de mode majeur / mineur et m'assurer que ma liaison est toujours en vigueur.

Cela ne fonctionne bien sûr pas:

(global-set-key "\C-i" 'some-function)

Ca marche dedans text-mode, mais quand je l'utilise lisp-mode, C-ic'est rebondir lisp-indent-line.

Je peux passer et remplacer cette liaison dans lisp-modeet dans tous les autres modes individuellement, mais il doit y avoir un moyen plus simple. Chaque fois que j'installe un nouveau mode pour un nouveau type de fichier, je devrais revenir en arrière et vérifier que toutes mes combinaisons de touches ne sont pas remplacées par le nouveau mode.

Je veux faire cela parce que je veux émuler des liaisons que j'ai déjà apprises et enracinées auprès d'autres éditeurs.

J'utilise un mode mineur pour toutes mes raccourcis clavier:

(defvar my-keys-minor-mode-map
  (let ((map (make-sparse-keymap)))
    (define-key map (kbd "C-i") 'some-function)
    map)
  "my-keys-minor-mode keymap.")

(define-minor-mode my-keys-minor-mode
  "A minor mode so that my key settings override annoying major modes."
  :init-value t
  :lighter " my-keys")

(my-keys-minor-mode 1)

Cela a l'avantage supplémentaire de pouvoir désactiver toutes mes modifications d'un seul coup (désactivez simplement le mode mineur) au cas où quelqu'un d'autre conduirait le clavier ou si j'ai besoin de voir ce que fait une liaison de touche par défaut.

Notez que vous devrez peut-être désactiver cette option dans le mini-tampon:

(defun my-minibuffer-setup-hook ()
  (my-keys-minor-mode 0))

(add-hook 'minibuffer-setup-hook 'my-minibuffer-setup-hook)

En complément de la réponse de Scottfrazer , j'ai écrit ce qui suit afin que mes raccourcis clavier conservent la priorité, même si les bibliothèques chargées par la suite apportent leurs propres keymaps.

Parce que les keymaps peuvent être générés au moment de la compilation, cela loadsemblait être le meilleur endroit pour le faire.

(add-hook 'after-load-functions 'my-keys-have-priority)

(defun my-keys-have-priority (_file)
  "Try to ensure that my keybindings retain priority over other minor modes.

Called via the `after-load-functions' special hook."
  (unless (eq (caar minor-mode-map-alist) 'my-keys-minor-mode)
    (let ((mykeys (assq 'my-keys-minor-mode minor-mode-map-alist)))
      (assq-delete-all 'my-keys-minor-mode minor-mode-map-alist)
      (add-to-list 'minor-mode-map-alist mykeys))))

Installez use-package, évaluez et vous avez terminé:

(require 'bind-key)
(bind-key* "C-i" 'some-function)

J'ai trouvé cette question en cherchant "emacs undefine org mode keybindings", parce que je voulais dissocier le comportement Cc Cb existant pour permettre à ma carte globale de bury-buffer de fonctionner dans un buffer org.

Cela a fini par être la solution la plus simple pour moi:

(add-hook 'org-mode-hook
      (lambda ()
        (local-unset-key (kbd "C-c C-b"))))

Bien que la réponse de Scottfrazer soit exactement ce que vous avez demandé, je mentionnerai pour la postérité une autre solution.

À partir du manuel Emacs :

"Ne définissez pas la lettre Cc comme une clé dans les programmes Lisp. Les séquences composées de Cc et d'une lettre (majuscule ou minuscule) sont réservées aux utilisateurs; ce sont les seules séquences réservées aux utilisateurs, ne les bloquez donc pas."

Si vous liez vos liaisons globales personnelles à Cc plus une lettre, alors vous «devriez» être en sécurité. Cependant, il ne s'agit que d'une convention et n'importe quel mode est toujours capable de remplacer vos liaisons.

Si vous voulez "toujours utiliser les raccourcis clavier dans la carte, à moins que je ne les remplace explicitement pour une carte de mode spécifique", et en supposant que vous utilisez l'approche de scottfrazier , vous voulez:

(defun locally-override (key cmd)
  (unless (local-variable-p 'my-keys-minor-mode-map)
    (set (make-variable-buffer-local 'my-keys-minor-mode-map)
         (make-sparse-keymap))
    (set-keymap-parent my-keys-minor-mode-map 
                       (default-value 'my-keys-minor-mode-map)))
  (define-key my-keys-minor-mode-map key cmd))

Alors

(locally-override "\C-i" nil)

devrait supprimer la liaison "\ Ci" du mode mineur dans le tampon courant uniquement. Attention: ceci n'a pas été testé, mais semble être la bonne approche. Le point de définir le parent plutôt que de simplement copier la valeur globale de my-keys-minor-mode-map est que toute modification ultérieure de la valeur globale est automatiquement reflétée dans la valeur locale.

Je ne pense pas que vous puissiez. Cela revient à peu près à dire que vous voulez définir une variable globale qui ne peut pas être masquée par les déclarations de variables locales dans les fonctions. La portée ne fonctionne tout simplement pas de cette façon.

Cependant, il peut y avoir un moyen d'écrire une fonction elisp pour parcourir la liste des modes et la réaffecter dans chacun d'eux pour vous.

À moins que vous ne vouliez vraiment le faire vous-même, vous devriez vérifier et voir si quelqu'un d'autre l'a déjà fait.

Il existe un package pour Emacs qui donne à vos raccourcis clavier de type Windows. Vous devriez pouvoir le trouver via google.