Comment tester si un exécutable existe dans le% PATH% à partir d'un fichier batch Windows?

Je recherche un moyen simple de tester si un exécutable existe dans la variable d'environnement PATH à partir d'un fichier batch Windows.

L'utilisation d'outils externes non fournis par le système d'exploitation n'est pas autorisée. La version minimale de Windows requise est Windows XP.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Si vous en avez besoin pour différentes extensions, répétez simplement PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

Peut-être que cela whereexiste déjà sur les versions héritées de Windows, mais je n'y ai pas accès, donc je ne peux pas le dire. Sur ma machine, ce qui suit fonctionne également:

where myExecutable

et retourne avec un code de sortie différent de zéro s'il est introuvable. Dans un lot, vous souhaitez probablement également rediriger la sortie vers NUL.

Gardez à l'esprit

L'analyse dans les .batfichiers batch ( ) et sur la ligne de commande diffère (car les fichiers batch ont %0- %9), vous devez donc doubler le %. Sur la ligne de commande, ce n'est pas nécessaire, donc les variables sont justes %X.

Windows Vista et les versions ultérieures sont fournis avec un programme appelé where.exequi recherche les programmes dans le chemin. Cela fonctionne comme ceci:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Pour une utilisation dans un fichier de commandes, vous pouvez utiliser le /qcommutateur, qui définit simplement ERRORLEVELet ne produit aucune sortie.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Ou une version abrégée simple (mais moins lisible) qui imprime le message et quitte votre application:

where /q myapplication || ECHO Cound not find app. && EXIT /B

Voici une solution simple qui tente d'exécuter l'application et gère toute erreur par la suite .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Le code d'erreur 9009 signifie généralement que le fichier est introuvable.

Le seul inconvénient est qu'il file.exeest effectivement exécuté s'il est trouvé (ce qui dans certains cas n'est pas souhaitable).

Cela peut être accompli via la substitution de paramètres.

%~$PATH:1

Cela renvoie le chemin complet du nom de fichier exécutable dans% 1, sinon une chaîne vide.

Cela ne fonctionne pas avec les variables définies par l'utilisateur. Donc, si le nom de fichier exécutable n'est pas un paramètre de votre script, vous avez besoin d'un sous-programme. Par exemple:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Voir http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

Parfois, cette solution simple fonctionne, où vous vérifiez si la sortie correspond à ce que vous attendez. La première ligne exécute la commande et saisit la dernière ligne de sortie standard.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Si vous recherchez quelque chose comme moi dans le dossier de démarrage, vous devriez aller dans le dossier. Par exemple, je recherche exe sur le dossier de démarrage et j'utilise ce code comme

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Utilisez la commande: powershell Test-Path "exe que vous recherchez"

Il retournera True s'il est présent, sinon False.

Pour ceux qui recherchent une option PowerShell. Vous pouvez utiliser l' Get-Commandapplet de commande en passant deux éléments. Donnez d'abord l'emplacement actuel du répertoire avec le .\préfixe, puis donnez simplement le nom de l'exe.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

Cela retournera vrai si trouvé local ou dans des chemins d'accès à l'échelle du système.