Comment copier une structure de répertoires mais n'inclure que certains fichiers (à l'aide de fichiers batch Windows)

Comme le titre l'indique, comment puis-je copier récursivement une structure de répertoires mais n'inclure que certains fichiers. Par exemple, étant donné la structure de répertoires suivante:

folder1
  folder2
    folder3
      data.zip
      info.txt
      abc.xyz
    folder4
    folder5
      data.zip
      somefile.exe
      someotherfile.dll

Les fichiers data.zip et info.txt peuvent apparaître partout dans la structure des répertoires. Comment puis-je copier la structure complète du répertoire, mais n'inclure que les fichiers nommés data.zip et info.txt (tous les autres fichiers doivent être ignorés)?

La structure de répertoires résultante devrait ressembler à ceci:

copy_of_folder1
  folder2
    folder3
      data.zip
      info.txt
    folder4
    folder5
      data.zip

Vous ne mentionnez pas s'il doit s'agir uniquement de lots, mais si vous pouvez utiliser ROBOCOPY, essayez ceci:

ROBOCOPY C:\Source C:\Destination data.zip info.txt /E

EDIT: Changement du /Sparamètre /Epour inclure les dossiers vides.

Une solution alternative qui copie un fichier à la fois et ne nécessite pas ROBOCOPY:

@echo off
setlocal enabledelayedexpansion

set "SOURCE_DIR=C:\Source"
set "DEST_DIR=C:\Destination"
set FILENAMES_TO_COPY=data.zip info.txt

for /R "%SOURCE_DIR%" %%F IN (%FILENAMES_TO_COPY%) do (
    if exist "%%F" (
        set FILE_DIR=%%~dpF
        set FILE_INTERMEDIATE_DIR=!FILE_DIR:%SOURCE_DIR%=!
        xcopy /E /I /Y "%%F" "%DEST_DIR%!FILE_INTERMEDIATE_DIR!"
    )
)

L'instruction for externe génère toute combinaison de chemin possible de sous-répertoire in SOURCE_DIRet name in FILENAMES_TO_COPY. Pour chaque fichier existant, xcopy est appelé. FILE_INTERMEDIATE_DIRcontient le chemin du sous-répertoire du fichier dans SOURCE_DIRlequel doit être créé DEST_DIR.

essayez de rediriger la sortie de find (c'est-à-dire le chemin du fichier) dans cpio

find . -type f -name '*.jpg' | cpio -p -d -v targetdir/

cpio vérifie l'horodatage des fichiers cibles - c'est donc sûr et rapide.

supprimez -v pour une opération plus rapide, une fois que vous vous y êtes habitué.

Si Powershell est une option, vous pouvez le faire:

Copy-Item c:\sourcePath d:\destinationPath -filter data.zip -recurse

Le principal inconvénient est qu'il copie tous les dossiers, même s'ils finiront par être vides car aucun fichier ne correspond au filtre que vous spécifiez. Vous pourriez donc vous retrouver avec une arborescence pleine de dossiers vides, en plus des quelques dossiers contenant les fichiers souhaités.

Merci aux réponses précédentes. :)

Ce script nommé "r4k4copy.cmd":

@echo off
for %%p in (SOURCE_DIR DEST_DIR FILENAMES_TO_COPY) do set %%p=
cls
echo :: Copy Files Including Folder Tree
echo :: http://stackoverflow.com
rem     /questions/472692/how-to-copy
rem     -a-directory-structure-but-only
rem     -include-certain-files-using-windows
echo :: ReScripted by r4k4
echo.
if "%1"=="" goto :NoParam
if "%2"=="" goto :NoParam
if "%3"=="" goto :NoParam
setlocal enabledelayedexpansion
set SOURCE_DIR=%1
set DEST_DIR=%2
set FILENAMES_TO_COPY=%3
for /R "%SOURCE_DIR%" %%F IN (%FILENAMES_TO_COPY%) do (
if exist "%%F" (
set FILE_DIR=%%~dpF
set FILE_INTERMEDIATE_DIR=!FILE_DIR:%SOURCE_DIR%=!
xcopy /E /I /Y "%%F" "%DEST_DIR%!FILE_INTERMEDIATE_DIR!"
)
)
goto :eof
:NoParam
echo.
echo Syntax: %0 [Source_DIR] [Dest_DIR] [FileName]
echo Eg.   : %0 D:\Root E:\Root\Lev1\Lev2\Lev3 *.JPG
echo Means : Copy *.JPG from D:\Root to E:\Root\Lev1\Lev2\Lev3

Il accepte les variables "Source", "Destination" et "FileName". Il ne peut également copier que le type spécifié de fichiers ou des noms de fichiers sélectifs.

Toute amélioration est la bienvenue. :)

Avec find et cp uniquement:

mkdir /tmp/targetdir
cd sourcedir
find . -type f -name '*.zip' -exec cp -p --parents {} /tmp/targetdir ";"
find . -type f -name '*.txt' -exec cp -p --parents {} /tmp/targetdir ";"

Similaire à la solution de Paulius, mais les fichiers qui ne vous intéressent pas ne sont pas copiés puis supprimés:

@echo OFF

:: Replace c:\temp with the directory where folder1 resides.
cd c:\temp

:: You can make this more generic by passing in args for the source and destination folders.
for /f "usebackq" %%I in (`dir /b /s /a:-d folder1`) do @echo %%~nxI | find /V "data.zip" | find /v "info.txt" >> exclude_list.txt
xcopy folder1 copy_of_folder1 /EXCLUDE:exclude_list.txt /E /I

Pour copier tous les fichiers texte dans G: et conserver la structure des répertoires:

xcopy *.txt /s G:

Ce ne sont que deux commandes simples, mais je ne le recommanderais pas, à moins que les fichiers que vous n'avez PAS besoin de copier soient petits. C'est parce que cela copiera TOUS les fichiers, puis supprimera les fichiers qui ne sont pas nécessaires dans la copie.

xcopy /E /I folder1 copy_of_folder1
for /F "tokens=1 delims=" %i in ('dir /B /S /A:-D copy_of_files ^| find /V "info.txt" ^| find /V "data.zip"') do del /Q "%i"

Bien sûr, la deuxième commande est assez longue, mais ça marche!

De plus, cette approche ne vous oblige pas à télécharger et installer des outils tiers (Windows 2000+ BATCH a suffisamment de commandes pour cela).

Sous Linux et d'autres systèmes UNIX, l'utilisation de la tarcommande le ferait facilement.

$ tar cvf /tmp/full-structure.tar *data.zip *info.txt

Ensuite, vous cwd à la cible et:

$ tar xvf /tmp/full-structure.tar 

Bien sûr, vous pouvez diriger la sortie du premier tar vers le second, mais le voir fonctionner par étapes est plus facile à comprendre et à expliquer. Il me manque le cd / to / new / path / nécessaire dans la commande suivante - je ne me souviens simplement pas comment le faire maintenant. Quelqu'un d'autre peut l'ajouter, espérons-le.

$ tar cvf -  *data.zip *info.txt |  tar xvf - 

Tar (gnutar) est également disponible sur Windows, mais j'utiliserais probablement la xcopyméthode moi-même sur cette plate-forme.

XCOPY /S folder1\data.zip copy_of_folder1  
XCOPY /S folder1\info.txt copy_of_folder1

EDIT: Si vous souhaitez conserver les dossiers vides (qui, en relisant votre message, vous semblez utiliser) / E au lieu de / S.

À l'aide de l'interface de ligne de commande WinRAR, vous pouvez copier les noms de fichiers et / ou les types de fichiers dans une archive. Ensuite, vous pouvez extraire cette archive à l'emplacement de votre choix. Cela préserve la structure de fichier d'origine.

J'avais besoin d'ajouter des fichiers d'image d'album manquants à mon téléphone portable sans avoir à recopier la musique elle-même. Heureusement, la structure des répertoires était la même sur mon ordinateur et mon mobile!

J'ai utilisé:

   rar a -r C:\Downloads\music.rar X:\music\Folder.jpg

• C: \ Downloads \ music.rar = Archive à créer
• X: \ music \ = Dossier contenant des fichiers musicaux
• Folder.jpg = Nom de fichier que je voulais copier

Cela a créé une archive avec tous les fichiers Folder.jpg dans les sous-répertoires appropriés.

Cette technique peut également être utilisée pour copier des types de fichiers. Si les fichiers avaient tous des noms différents, vous pouvez choisir d'extraire tous les fichiers dans un seul répertoire. Des paramètres de ligne de commande supplémentaires peuvent archiver plusieurs types de fichiers.

Plus d'informations dans ce lien très utile http://cects.com/using-the-winrar-command-line-tools-in-windows/

Pour ceux qui utilisent Altap Salamander (gestionnaire de fichiers 2 panneaux): dans les Options de la popup Copier, il suffit de spécifier les noms de fichiers ou les masques. Facile.

Je suis d'accord avec les expressions régulières, paresseux et opposé aux installations, j'ai donc créé un fichier de commandes qui crée le répertoire et des copies avec des commandes DOS vanille. Cela me semble laborieux mais plus rapide que de travailler sur la robocopie.

1. Créez votre liste de fichiers source avec des chemins complets, y compris la lettre de lecteur si nécessaire, dans un fichier texte.
2. Activez les expressions régulières dans votre éditeur de texte.
3. Ajouter des guillemets doubles autour de chaque ligne en cas d'espaces - la chaîne de recherche (.*)remplace la chaîne"\1" et cliquez sur tout remplacer
4. Créez deux lignes par fichier - une pour créer le répertoire, une pour copier le fichier (qqq sera remplacé par le chemin de destination) - la chaîne de recherche (.*)remplace la chaîne md qqq\1\nxcopy \1 qqq\1\net cliquez sur remplacer tout
5. Supprimer le nom de fichier des chemins de destination - \\([^\\^"]+)"\nremplacement de la recherche\\"\n
6. Remplacez dans le chemin de destination (dans cet exemple A:\srcet B:\dest). Désactivez les expressions régulières, recherchez qqq"A:\src\remplacer B:\dest\et cliquez sur tout remplacer.

md créera des répertoires imbriqués. copy se comporterait probablement de la même manière que xcopy dans cet exemple. Vous pouvez ajouter / Y à xcopy pour supprimer les confirmations d'écrasement. Vous vous retrouvez avec un fichier batch comme ceci:

md "B:\dest\a\b\c\"
xcopy "C:\src\a\b\c\e.xyz" "B:\dest\a\b\c\e.xyz"

répété pour chaque fichier de votre liste d'origine. Testé sur Win7.

Pour ce faire par glisser-déposer, utilisez winzip, il existe une option de préservation de la structure dir. Créez simplement un nouveau .zip au niveau du répertoire qui sera votre racine et faites-y glisser les fichiers.