Aliaser une commande dans vim

Vim est mon éditeur de texte préféré lorsque je programme, et donc je rencontre toujours un problème particulièrement ennuyeux.

Souvent, lorsque je dois rapidement enregistrer le tampon et passer à une autre tâche diverse, je fais le typique

:w

Cependant, je - ce qui semble être plus de 50% du temps - parviens toujours à capitaliser cela :w. Naturellement, vim me crie dessus parce que Wc'est une commande invalide

E492: Not an editor command: W

Ma question est de savoir comment un alias deux-points-commandes dans vim . En particulier, pourriez-vous illustrer comment créer un alias Wvers w.

Je connais le processus de mappage des clés vers certaines commandes . Malheureusement, ce n'est pas ce que je recherche.

Pour ne pas modifier l’achèvement, essayez d’utiliser

cnoreabbrev W w

, il remplacera Wen ligne de commande par w, mais seulement s'il n'est ni suivi ni précédé d'un caractère mot, il :W<CR>sera donc remplacé par :w<CR>, mais :Writene le fera pas. (Notez que cela affecte toutes les commandes qui correspondent, y compris celles auxquelles vous ne vous attendez peut-être pas, par exemple, la commande :saveas W Zsera remplacée par :saveas w Z, alors soyez prudent avec cela.)

Mettre à jour

Voici comment je l'écrirais maintenant :

cnoreabbrev <expr> W ((getcmdtype() is# ':' && getcmdline() is# 'W')?('w'):('W'))

En tant que fonction:

fun! SetupCommandAlias(from, to)
  exec 'cnoreabbrev <expr> '.a:from
        \ .' ((getcmdtype() is# ":" && getcmdline() is# "'.a:from.'")'
        \ .'? ("'.a:to.'") : ("'.a:from.'"))'
endfun
call SetupCommandAlias("W","w")

Cela vérifie que le type de commande est :et la commande est W, donc c'est plus sûr que juste cnoreabbrev W w.

Avec une recherche supplémentaire, j'ai constaté que quelqu'un avait posé à peu près la même question que moi.

:command <AliasName> <string of command to be aliased>

fera l'affaire.

Veuillez noter que, comme noter souligne Richo , la commande utilisateur doit commencer par une majuscule.

Je trouve que mapper la ;clé :serait une meilleure solution et vous rendrait plus productif pour taper d'autres commandes.

nnoremap ; :
vnoremap ; :

La meilleure solution consiste à écrire une fonction personnalisée pour gérer les abréviations qui n'ont lieu qu'au début de la barre de commandes.

Pour cela, ajoutez ce qui suit à votre fichier vimrc ou ailleurs.

" cabs - less stupidity                                                      {{{
fu! Single_quote(str)
  return "'" . substitute(copy(a:str), "'", "''", 'g') . "'"
endfu
fu! Cabbrev(key, value)
  exe printf('cabbrev <expr> %s (getcmdtype() == ":" && getcmdpos() <= %d) ? %s : %s',
    \ a:key, 1+len(a:key), Single_quote(a:value), Single_quote(a:key))
endfu
"}}}

" use this custom function for cabbrevations. This makes sure that they only
" apply in the beginning of a command. Else we might end up with stuff like
"   :%s/\vfoo/\v/\vbar/
" if we happen to move backwards in the pattern.

" For example:
call Cabbrev('W', 'w')

Quelques abréviations utiles du matériel source où j'ai trouvé ce truc:

call Cabbrev('/',   '/\v')
call Cabbrev('?',   '?\v')

call Cabbrev('s/',  's/\v')
call Cabbrev('%s/', '%s/\v')

call Cabbrev('s#',  's#\v')
call Cabbrev('%s#', '%s#\v')

call Cabbrev('s@',  's@\v')
call Cabbrev('%s@', '%s@\v')

call Cabbrev('s!',  's!\v')
call Cabbrev('%s!', '%s!\v')

call Cabbrev('s%',  's%\v')
call Cabbrev('%s%', '%s%\v')

call Cabbrev("'<,'>s/", "'<,'>s/\v")
call Cabbrev("'<,'>s#", "'<,'>s#\v")
call Cabbrev("'<,'>s@", "'<,'>s@\v")
call Cabbrev("'<,'>s!", "'<,'>s!\v")

Vous souhaitez peut-être mapper l'une de vos touches de fonction (F1..F12) sur: w? Ensuite, mettez ceci dans votre .vimrc:

noremap  <f1> :w<return>
inoremap <f1> <c-o>:w<return>

(ctrl-o en mode insertion passe temporairement en mode normal).

Supposons que vous souhaitiez ajouter un alias pour la commande tabnew dans gvim. vous pouvez simplement taper la commande suivante dans votre fichier .vimrc (si ce n'est pas dans le dossier personnel, créez-en un)

cabbrev t tabnew

Le plus sûr et le plus simple est un plugin tel que cmdalias.vim ou ma récente mise à jour vim-alias de celui-ci qui prend en compte

• les espaces ou les modificateurs précédents tels que :sil(ent)(!)ou :redi(r),
• des modificateurs de plage tels que '<,'>pour la sélection visuelle actuelle,
• échapper les caractères spéciaux tels que les guillemets et
• vérifiez si l'alias choisi est une abréviation de ligne de commande valide.