Comment obtenir la sortie d'une commande shell exécutée à l'aide d'une variable de Jenkinsfile (groovy)?

J'ai quelque chose comme ça sur un fichier Jenkins (Groovy) et je veux enregistrer la sortie standard et le code de sortie dans une variable afin d'utiliser les informations plus tard.

sh "ls -l"

Comment puis-je faire cela, d'autant plus qu'il semble que vous ne pouvez pas vraiment exécuter de code groovy à l'intérieur de Jenkinsfile?

La dernière version de l' shétape du pipeline vous permet d'effectuer les opérations suivantes;

// Git committer email
GIT_COMMIT_EMAIL = sh (
    script: 'git --no-pager show -s --format=\'%ae\'',
    returnStdout: true
).trim()
echo "Git committer email: ${GIT_COMMIT_EMAIL}"

Une autre caractéristique est l' returnStatusoption.

// Test commit message for flags
BUILD_FULL = sh (
    script: "git log -1 --pretty=%B | grep '\\[jenkins-full]'",
    returnStatus: true
) == 0
echo "Build full flag: ${BUILD_FULL}"

Ces options ont été ajoutées en fonction de ce problème.

Voir la documentation officielle de la shcommande.

La version actuelle du Pipeline prend en charge nativement returnStdoutet returnStatus, ce qui permet d'obtenir la sortie ou l'état à partir de sh/ batsteps.

Un exemple:

def ret = sh(script: 'uname', returnStdout: true)
println ret

Une documentation officielle .

la réponse rapide est la suivante:

sh "ls -l > commandResult"
result = readFile('commandResult').trim()

Je pense qu'il existe une demande de fonctionnalité pour pouvoir obtenir le résultat de l'étape sh, mais pour autant que je sache, il n'y a actuellement aucune autre option.

EDIT: JENKINS-26133

EDIT2: Je ne sais pas trop depuis quelle version, mais les étapes sh / bat peuvent maintenant retourner la sortie std, simplement:

def output = sh returnStdout: true, script: 'ls -l'

Si vous voulez obtenir la sortie standard ET savoir si la commande a réussi ou non, utilisez simplement returnStdout et encapsulez-la dans un gestionnaire d'exceptions:

pipeline scripté

try {
    // Fails with non-zero exit if dir1 does not exist
    def dir1 = sh(script:'ls -la dir1', returnStdout:true).trim()
} catch (Exception ex) {
    println("Unable to read dir1: ${ex}")
}

sortie :

[Pipeline] sh
[Test-Pipeline] Running shell script
+ ls -la dir1
ls: cannot access dir1: No such file or directory
[Pipeline] echo
unable to read dir1: hudson.AbortException: script returned exit code 2

Malheureusement, hudson.AbortException ne contient aucune méthode utile pour obtenir ce statut de sortie, donc si la valeur réelle est requise, vous devrez l'analyser hors du message (ugh!)

Contrairement au Javadoc https://javadoc.jenkins-ci.org/hudson/AbortException.html, la génération n'est pas échouée lorsque cette exception est interceptée. Il échoue quand il n'est pas pris!

Mise à jour: si vous souhaitez également la sortie STDERR de la commande shell, Jenkins ne parvient malheureusement pas à prendre correctement en charge ce cas d'utilisation courant. Un billet 2017 JENKINS-44930 est coincé dans un état de ping-pong avisé sans faire de progrès vers une solution - veuillez envisager d'y ajouter votre vote positif.

En ce qui concerne une solution maintenant , il pourrait y avoir deux approches possibles:

a) Redirigez STDERR vers STDOUT 2>&1 - mais c'est ensuite à vous de l'analyser hors de la sortie principale, et vous n'obtiendrez pas la sortie si la commande a échoué - parce que vous êtes dans le gestionnaire d'exceptions.

b) rediriger STDERR vers un fichier temporaire (dont vous préparez le nom plus tôt) 2>filename(mais n'oubliez pas de nettoyer le fichier par la suite) - ie. le code principal devient:

def stderrfile = 'stderr.out'
try {
    def dir1 = sh(script:"ls -la dir1 2>${stderrfile}", returnStdout:true).trim()
} catch (Exception ex) {
    def errmsg = readFile(stderrfile)
    println("Unable to read dir1: ${ex} - ${errmsg}")
}

c) Dans l'autre sens, définissez returnStatus=trueplutôt, supprimez le gestionnaire d'exceptions et capturez toujours la sortie dans un fichier, c'est-à-dire:

def outfile = 'stdout.out'
def status = sh(script:"ls -la dir1 >${outfile} 2>&1", returnStatus:true)
def output = readFile(outfile).trim()
if (status == 0) {
    // output is directory listing from stdout
} else {
    // output is error message from stderr
}

Attention: le code ci-dessus est spécifique à Unix / Linux - Windows nécessite des commandes shell complètement différentes.

ceci est un exemple de cas, ce qui aura du sens je crois!

node('master'){
    stage('stage1'){
    def commit = sh (returnStdout: true, script: '''echo hi
    echo bye | grep -o "e"
    date
    echo lol''').split()


    echo "${commit[-1]} "

    }
}

Pour ceux qui ont besoin d'utiliser la sortie dans les commandes shell suivantes, plutôt que groovy, quelque chose comme cet exemple pourrait être fait:

    stage('Show Files') {
        environment {
          MY_FILES = sh(script: 'cd mydir && ls -l', returnStdout: true)
        }
        steps {
          sh '''
            echo "$MY_FILES"
          '''
        }
    }

J'ai trouvé les exemples sur le code maven très utiles.

Le moyen le plus simple est d'utiliser de cette façon

my_var=`echo 2` echo $my_var sortie: 2

notez que ce n'est pas une simple citation simple, c'est une citation de retour (`).