J'obtiens des erreurs de 'espaces blancs' en essayant de valider certains fichiers dans git.

Je veux supprimer ces espaces blancs finaux automatiquement juste avant d'enregistrer des fichiers python.

Pouvez-vous configurer vim pour ce faire? Si c'est le cas, comment?

J'ai trouvé la réponse ici .

L'ajout de ce qui suit à mon fichier .vimrc a fait l'affaire.

autocmd BufWritePre *.py :%s/\s\+$//e

Compilation de ce qui précède et sauvegarde de la position du curseur:

fun! <SID>StripTrailingWhitespaces()
    let l = line(".")
    let c = col(".")
    keepp %s/\s\+$//e
    call cursor(l, c)
endfun

autocmd FileType c,cpp,java,php,ruby,python autocmd BufWritePre <buffer> :call <SID>StripTrailingWhitespaces()

Si vous souhaitez appliquer cela lors de l'enregistrement à n'importe quel fichier, omettez le second autocmdet utilisez un caractère générique *:

autocmd BufWritePre * :call <SID>StripTrailingWhitespaces()

J'ai aussi généralement:

match Todo /\s\+$/

dans mon .vimrcfichier, afin que les blancs de fin de ligne soient mis en évidence.

Todo étant un nom de groupe de syntaxe hilighting utilisé pour les mots clés hilighting comme TODO, FIXMEou XXX. Il a une couleur de fond jaunâtre ennuyeusement laide, et je trouve que c'est le meilleur pour mettre en évidence les choses que vous ne voulez pas dans votre code :-)

Je souligne à la fois les espaces blancs finaux existants et je dépouille également les espaces blancs finaux.

Je configure mon éditeur (vim) pour afficher un espace blanc à la fin, par exemple

avec ceci au bas de mon .vimrc:

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

et je le «supprime automatiquement» des fichiers lors de leur enregistrement, dans mon cas * .rb pour les fichiers ruby, à nouveau dans mon ~ / .vimrc

function! TrimWhiteSpace()
    %s/\s\+$//e
endfunction
autocmd BufWritePre     *.rb :call TrimWhiteSpace()

Voici un moyen de filtrer par plus d'un FileType.

autocmd FileType c,cpp,python,ruby,java autocmd BufWritePre <buffer> :%s/\s\+$//e

Copié et collé depuis http://blog.kamil.dworakowski.name/2009/09/unobtrusive-highlighting-of-trailing.html (le lien ne fonctionne plus, mais le bit dont vous avez besoin est ci-dessous)

"Cela a l'avantage de ne pas mettre en surbrillance chaque espace que vous tapez à la fin de la ligne, uniquement lorsque vous ouvrez un fichier ou quittez le mode d'insertion. Très soigné."

highlight ExtraWhitespace ctermbg=red guibg=red
au ColorScheme * highlight ExtraWhitespace guibg=red
au BufEnter * match ExtraWhitespace /\s\+$/
au InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
au InsertLeave * match ExtraWhiteSpace /\s\+$/

J'ai vu cette solution dans un commentaire à VIM Wikia - Supprimer les espaces indésirables

J'aime vraiment ça. Ajoute un .sur les espaces blancs indésirables.

Mettez ça dans votre .vimrc

" Removes trailing spaces
function TrimWhiteSpace()
  %s/\s*$//
  ''
endfunction

set list listchars=trail:.,extends:>
autocmd FileWritePre * call TrimWhiteSpace()
autocmd FileAppendPre * call TrimWhiteSpace()
autocmd FilterWritePre * call TrimWhiteSpace()
autocmd BufWritePre * call TrimWhiteSpace()

Voilà comment je le fais. Je ne me souviens pas où je l'ai volé à tbh.

autocmd BufWritePre * :call <SID>StripWhite()
fun! <SID>StripWhite()
    %s/[ \t]\+$//ge
    %s!^\( \+\)\t!\=StrRepeat("\t", 1 + strlen(submatch(1)) / 8)!ge
endfun

Une solution qui supprime simplement les espaces de fin du fichier n'est pas acceptable en toutes circonstances. Cela fonctionnera dans un projet qui a eu cette politique depuis le début, et donc il n'y a pas de tels espaces que vous ne vous êtes pas simplement ajoutés dans votre prochain commit.

Supposons que vous souhaitiez simplement ne pas ajouter de nouvelles instances d'espaces de fin, sans affecter les espaces existants dans les lignes que vous n'avez pas modifiées, afin de garder votre validation exempte de modifications qui ne sont pas pertinentes pour votre travail.

Dans ce cas, avec git, vous pouvez utiliser un script comme celui-ci:

#!/bin/sh

set -e # bail on errors

git stash save commit-cleanup
git stash show -p | sed '/^\+/s/ *$//' | git apply
git stash drop

C'est-à-dire que nous cachons les modifications, puis filtrons toutes les +lignes dans le diff pour supprimer leurs espaces de fin lorsque nous réappliquons les modifications au répertoire de travail. Si ce canal de commande réussit, nous supprimons la cachette.

Les autres approches ici n'ont pas fonctionné pour moi dans MacVim lorsqu'elles sont utilisées dans le .vimrcfichier. Voici donc un qui fait et met en évidence les espaces de fin:

set encoding=utf-8
set listchars=trail:·
set list

autocmd BufWritePre * :%s/\s\+$//<CR>:let @/=''<CR>

Pour les personnes qui souhaitent l'exécuter pour des types de fichiers spécifiques (les FileTypes ne sont pas toujours fiables):

autocmd BufWritePre *.c,*.cpp,*.cc,*.h,*.hpp,*.py,*.m,*.mm :%s/\s\+$//e

Ou avec vim7:

autocmd BufWritePre *.{c,cpp,cc,h,hpp,py,m,mm} :%s/\s\+$//e

Si vous coupez des espaces, vous devez seulement le faire sur les fichiers qui sont déjà propres. "Quand à Rome ...". C'est une bonne étiquette lorsque vous travaillez sur des bases de code où des modifications parasites ne sont pas les bienvenues.

Cette fonction détecte les espaces vides et n'active le rognage que s'il était déjà propre.

Le mérite de cette idée revient à un joyau d'un commentaire ici: https://github.com/atom/whitespace/issues/10 (le plus long flux de commentaires de tickets de bogue jamais)

autocmd BufNewFile,BufRead *.test call KarlDetectWhitespace()

fun! KarlDetectWhitespace()
python << endpython
import vim
nr_unclean = 0
for line in vim.current.buffer:
    if line.rstrip() != line:
        nr_unclean += 1

print "Unclean Lines: %d" % nr_unclean
print "Name: %s" % vim.current.buffer.name
cmd = "autocmd BufWritePre <buffer> call KarlStripTrailingWhitespace()"
if nr_unclean == 0:
    print "Enabling Whitespace Trimming on Save"
    vim.command(cmd)
else:
    print "Whitespace Trimming Disabled"
endpython
endfun

fun! KarlStripTrailingWhitespace()
    let l = line(".")
    let c = col(".")
    %s/\s\+$//e
    call cursor(l, c)
endfun