J'ai besoin de tester si une variable est définie ou non. J'ai essayé plusieurs techniques , mais ils semblent échouer à chaque fois %1est entouré par des guillemets comme le cas où %1est "c:\some path with spaces".

IF NOT %1 GOTO MyLabel // This is invalid syntax
IF "%1" == "" GOTO MyLabel // Works unless %1 has double quotes which fatally kills bat execution
IF %1 == GOTO MyLabel // Gives an unexpected GOTO error.

Selon ce site , ce sont les IFtypes de syntaxe pris en charge . Donc, je ne vois pas de moyen de le faire.

IF [NOT] ERRORLEVEL number command
IF [NOT] string1==string2 command
IF [NOT] EXIST filename command

Utilisez des crochets au lieu des guillemets:

IF [%1] == [] GOTO MyLabel

Les parenthèses ne sont pas sécurisées : utilisez uniquement des crochets.

Vous pouvez utiliser:

IF "%~1" == "" GOTO MyLabel

pour supprimer l'ensemble extérieur de guillemets. En général, c'est une méthode plus fiable que l'utilisation de crochets car elle fonctionnera même si la variable contient des espaces.

L'une des meilleures solutions semi est de copier %1dans une variable, puis d'utiliser une expansion retardée, comme retardExp. est toujours à l'abri de tout contenu.

set "param1=%~1"
setlocal EnableDelayedExpansion
if "!param1!"=="" ( echo it is empty )
rem ... or use the DEFINED keyword now
if defined param1 echo There is something

L'avantage de cela est que le traitement de param1 est absolument sûr.

Et le réglage de param1 fonctionnera dans de nombreux cas, comme

test.bat hello"this is"a"test
test.bat you^&me

Mais il échoue toujours avec des contenus étranges comme

test.bat ^&"&

Pour pouvoir obtenir une réponse 100% correcte à l'existence

Il détecte si %1est vide, mais pour certains contenus, il ne peut pas récupérer le contenu.
Cela peut également être utile pour faire la distinction entre un vide %1et un avec "".
Il utilise la capacité de la CALLcommande à échouer sans abandonner le fichier de commandes.

@echo off
setlocal EnableDelayedExpansion
set "arg1="
call set "arg1=%%1"

if defined arg1 goto :arg_exists

set "arg1=#"
call set "arg1=%%1"
if "!arg1!" EQU "#" (
    echo arg1 exists, but can't assigned to a variable
    REM Try to fetch it a second time without quotes
    (call set arg1=%%1)
    goto :arg_exists
)

echo arg1 is missing
exit /b

:arg_exists
echo arg1 exists, perhaps the content is '!arg1!'

Si vous voulez être à 100% à l'épreuve des balles pour récupérer le contenu, vous pouvez lire Comment recevoir même les paramètres de ligne de commande les plus étranges?

De IF /?:

Si les extensions de commande sont activées, IF change comme suit:

IF [/I] string1 compare-op string2 command
IF CMDEXTVERSION number command
IF DEFINED variable command

......

Le conditionnel DEFINED fonctionne exactement comme EXISTS, sauf qu'il prend un nom de variable d'environnement et renvoie true si la variable d'environnement est définie.

Malheureusement, je n'ai pas assez de réputation pour commenter ou voter sur les réponses actuelles car j'ai dû écrire les miennes.

À l'origine, la question du PO parlait de "variable" plutôt que de "paramètre", ce qui est devenu très déroutant, d'autant plus qu'il s'agissait du lien numéro un dans Google pour rechercher comment tester les variables vides. Depuis ma réponse d'origine, Stephan a modifié la question d'origine pour utiliser la terminologie correcte, mais plutôt que de supprimer ma réponse, j'ai décidé de la laisser pour dissiper toute confusion, en particulier dans le cas où Google envoie encore des gens ici pour des variables:

% 1 N'EST PAS UN VARABLE! C'EST UN PARAMÈTRE DE LIGNE DE COMMANDE.

Distinction très importante. Un signe de pourcentage unique avec un nombre après qu'il se réfère à un paramètre de ligne de commande et non à une variable.

Les variables sont définies à l'aide de la commande set et sont rappelées à l'aide de signes à 2% - un avant et un après. Par exemple% myvar%

Pour tester une variable vide, vous utilisez la syntaxe "si non définie" (les commandes explicites pour les variables ne nécessitent aucun signe de pourcentage), par exemple:

set myvar1=foo  
if not defined myvar1 echo You won't see this because %myvar1% is defined.  
if not defined myvar2 echo You will see this because %myvar2% isn't defined.

(Si vous souhaitez tester les paramètres de ligne de commande, je vous recommande de vous référer à la réponse de jamesdlin.)

Utilisez "IF DEFINED variable command" pour tester la variable dans le fichier de commandes.

Mais si vous voulez tester les paramètres du lot, essayez les codes ci-dessous pour éviter les entrées délicates (comme "1 2" ou ab ^> cd)

set tmp="%1"
if "%tmp:"=.%"==".." (
    echo empty
) else (
    echo not empty
)

Je teste avec le code ci-dessous et c'est très bien.

@echo off

set varEmpty=
if not "%varEmpty%"=="" (
    echo varEmpty is not empty
) else (
    echo varEmpty is empty
)
set varNotEmpty=hasValue
if not "%varNotEmpty%"=="" (
    echo varNotEmpty is not empty
) else (
    echo varNotEmpty is empty
)

J'utilise habituellement ceci:

IF "%1."=="." GOTO MyLabel

Si% 1 est vide, l'IF comparera "." à "." qui sera évalué à vrai.

J'ai créé ce petit script batch basé sur les réponses ici, car il y en a beaucoup de valides. N'hésitez pas à ajouter à cela tant que vous suivez le même format:

REM Parameter-testing

Setlocal EnableDelayedExpansion EnableExtensions

IF NOT "%~1"=="" (echo Percent Tilde 1 failed with quotes) ELSE (echo SUCCESS)
IF NOT [%~1]==[] (echo Percent Tilde 1 failed with brackets) ELSE (echo SUCCESS)
IF NOT  "%1"=="" (echo Quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1]==[] (echo Brackets one failed) ELSE (echo SUCCESS)
IF NOT "%1."=="." (echo Appended dot quotes one failed) ELSE (echo SUCCESS)
IF NOT [%1.]==[.] (echo Appended dot brackets one failed) ELSE (echo SUCCESS)

pause

La chaîne vide est une paire de double-quotes/ "", nous pouvons simplement tester la longueur:

set ARG=%1
if not defined ARG goto nomore

set CHAR=%ARG:~2,1%
if defined CHAR goto goon

puis testez 2 caractères contre double-quotes:

if ^%ARG:~1,1% == ^" if ^%ARG:~0,1% == ^" goto blank
::else
goto goon

Voici un script batch avec lequel vous pouvez jouer. Je pense qu'il attrape correctement la chaîne vide.

Ceci est juste un exemple, vous avez juste besoin de personnaliser 2 (ou 3?) Étapes ci-dessus en fonction de votre script.

@echo off
if not "%OS%"=="Windows_NT" goto EOF
:: I guess we need enableExtensions, CMIIW
setLocal enableExtensions
set i=0
set script=%0

:LOOP
set /a i=%i%+1

set A1=%1
if not defined A1 goto nomore

:: Assumption:
:: Empty string is (exactly) a pair of double-quotes ("")

:: Step out if str length is more than 2
set C3=%A1:~2,1%
if defined C3 goto goon

:: Check the first and second char for double-quotes
:: Any characters will do fine since we test it *literally*
if ^%A1:~1,1% == ^" if ^%A1:~0,1% == ^" goto blank
goto goon

:goon
echo.args[%i%]: [%1]
shift
goto LOOP

:blank
echo.args[%i%]: [%1] is empty string
shift
goto LOOP

:nomore
echo.
echo.command line:
echo.%script% %*

:EOF

Ce résultat du test de torture:

.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""
args[1]: [::]
args[2]: [""] is empty string
args[3]: [">"""bl" "]
args[4]: ["< "">"]
args[5]: [(")(")]
args[6]: [""] is empty string
args[7]: [::]
args[8]: [""-"  "]
args[9]: ["( )"">\>"]
args[10]: [""] is empty string

command line:
.test.bat :: ""  ">"""bl" " "< "">"  (")(") "" :: ""-"  " "( )"">\>" ""

Vous pouvez utiliser

if defined (variable) echo That's defined!
if not defined (variable) echo Nope. Undefined.

Script 1:

Entrée ("Remove Quotes.cmd" "Ceci est un test")

@ECHO OFF

REM Set "string" variable to "first" command line parameter
SET STRING=%1

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

REM IF %1 [or String] is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel


REM   OR   IF "." equals "." GOTO MyLabel
IF "%STRING%." == "." GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

PAUSE

Sortie (il n'y en a pas,% 1 n'était PAS vide, vide ou NULL):

Exécutez ("Remove Quotes.cmd") sans aucun paramètre avec le script ci-dessus 1

Sortie (% 1 est vide, vide ou NULL):

Welcome!

Press any key to continue . . .

Remarque: Si vous définissez une variable dans une IF ( ) ELSE ( )instruction, elle ne sera disponible pour DEFINED qu'après avoir quitté l'instruction "IF" (sauf si "Expansion de variable retardée" est activée; une fois activée, utilisez un point d'exclamation "!" À la place de la symbole de pourcentage "%"}.

Par exemple:

Script 2:

Entrée ("Remove Quotes.cmd" "Ceci est un test")

@ECHO OFF

SETLOCAL EnableDelayedExpansion

SET STRING=%0
IF 1==1 (
  SET STRING=%1
  ECHO String in IF Statement='%STRING%'
  ECHO String in IF Statement [delayed expansion]='!STRING!'
) 

ECHO String out of IF Statement='%STRING%'

REM Remove Quotes [Only Remove Quotes if NOT Null]
IF DEFINED STRING SET STRING=%STRING:"=%

ECHO String without Quotes=%STRING% 

REM IF %1 is NULL GOTO MyLabel
IF NOT DEFINED STRING GOTO MyLabel

REM GOTO End of File
GOTO :EOF

:MyLabel
ECHO Welcome!

ENDLOCAL
PAUSE

Production:

C:\Users\Test>"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd" "This is a Test"  
String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is a Test"'  
String out of IF Statement='"This is a Test"'  
String without Quotes=This is a Test  

C:\Users\Test>  

Remarque: Il supprimera également les guillemets de l'intérieur de la chaîne.

Par exemple (en utilisant le script 1 ou 2): C: \ Users \ Test \ Documents \ Batch Files> "Remove Quotes.cmd" "Ceci est" un "Test"

Sortie (Script 2):

String in IF Statement='"C:\Users\Test\Documents\Batch Files\Remove Quotes.cmd"'  
String in IF Statement [delayed expansion]='"This is "a" Test"'  
String out of IF Statement='"This is "a" Test"'  
String without Quotes=This is a Test  

Exécutez ("Remove Quotes.cmd") sans aucun paramètre dans le script 2:

Production:

Welcome!

Press any key to continue . . .

Pour résumer:

set str=%~1
if not defined str ( echo Empty string )

Ce code affichera "Chaîne vide" si% 1 est "" ou "ou vide. Ajouté à la réponse acceptée qui est actuellement incorrecte.

J'ai eu beaucoup de problèmes avec beaucoup de réponses sur le net. La plupart fonctionnent pour la plupart des choses, mais il y a toujours un cas d'angle qui casse chacun.
Peut-être que cela ne fonctionne pas s'il a des guillemets, peut-être qu'il se casse s'il n'a pas de guillemets, une erreur de syntaxe si le var a un espace, certains ne fonctionneront que sur les paramètres (par opposition aux variables d'environnement), d'autres techniques permettent un vide ensemble de guillemets à passer comme «définis», et certains plus délicats ne vous laisseront pas enchaîner elsepar la suite.

Voici une solution dont je suis satisfait, faites-le moi savoir si vous trouvez un cas d'angle pour lequel il ne fonctionnera pas.

:ifSet
if "%~1"=="" (Exit /B 1) else (Exit /B 0)

Avoir ce sous-programme soit dans votre script, soit dans le sien .bat, devrait fonctionner.
Donc si vous vouliez écrire (en pseudo):

if (var)
then something
else somethingElse

Tu peux écrire:

(Call :ifSet %var% && (
    Echo something
)) || (
    Echo something else
)

Cela a fonctionné pour tous mes tests:

(Call :ifSet && ECHO y) || ECHO n
(Call :ifSet a && ECHO y) || ECHO n
(Call :ifSet "" && ECHO y) || ECHO n
(Call :ifSet "a" && ECHO y) || ECHO n
(Call :ifSet "a a" && ECHO y) || ECHO n

Echo'd n, y, n, y,y

Plus d'exemples:

• Tu veux juste vérifier if?Call :ifSet %var% && Echo set
• Si non (seulement le reste)? Call :ifSet %var% || Echo set
• Vérification d'un argument passé; fonctionne bien.Call :ifSet %1 && Echo set
• Vous ne vouliez pas obstruer vos scripts / code dupe, alors vous le mettez dans le sien ifSet.bat? Aucun problème:((Call ifSet.bat %var%) && Echo set) || (Echo not set)

En utilisant ! au lieu de "pour la vérification de chaîne vide

@echo off
SET a=
SET b=Hello
IF !%a%! == !! echo String a is empty
IF !%b%! == !! echo String b is empty

Je suis entré il y a un peu moins d'un mois (même si cela a été demandé il y a 8 ans) ... J'espère qu'il / elle a déjà dépassé les fichiers batch. ;-) J'avais l'habitude de faire ça tout le temps. Je ne sais pas quel est le but ultime, cependant. S'il est paresseux comme moi, mon go.bat fonctionne pour des trucs comme ça. (Voir ci-dessous) Mais, 1, la commande dans l'OP peut être invalide si vous utilisez directement l'entrée en tant que commande. c'est à dire,

"C:/Users/Me"

est une commande non valide (ou utilisée si vous étiez sur un autre lecteur). Vous devez le casser en deux parties.

C:
cd /Users/Me

Et, 2, que signifie «défini» ou «non défini»? GIGO. J'utilise la valeur par défaut pour détecter les erreurs. Si l'entrée n'est pas interceptée, elle tombe pour aider (ou une commande par défaut). Donc, aucune entrée n'est pas une erreur. Vous pouvez essayer de cd à l'entrée et attraper l'erreur s'il y en a une. (Ok, utiliser les téléchargements go "(un seul paren) est pris par DOS. (Dur!))

cd "%1"
if %errorlevel% neq 0 goto :error

Et, 3, les guillemets sont nécessaires uniquement autour du chemin, pas de la commande. c'est à dire,

"cd C:\Users" 

était mauvais (ou habitué autrefois), sauf si vous étiez sur un autre lecteur.

cd "\Users" 

est fonctionnel.

cd "\Users\Dr Whos infinite storage space"

fonctionne si vous avez des espaces sur votre chemin.

@REM go.bat
@REM The @ sigh prevents echo on the current command
@REM The echo on/off turns on/off the echo command. Turn on for debugging
@REM You can't see this.
@echo off
if "help" == "%1" goto :help

if "c" == "%1" C:
if "c" == "%1" goto :done

if "d" == "%1" D:
if "d" == "%1" goto :done

if "home"=="%1" %homedrive%
if "home"=="%1" cd %homepath%
if "home"=="%1" if %errorlevel% neq 0 goto :error
if "home"=="%1" goto :done

if "docs" == "%1" goto :docs

@REM goto :help
echo Default command
cd %1
if %errorlevel% neq 0 goto :error
goto :done

:help
echo "Type go and a code for a location/directory
echo For example
echo go D
echo will change disks (D:)
echo go home
echo will change directories to the users home directory (%homepath%)
echo go pictures
echo will change directories to %homepath%\pictures
echo Notes
echo @ sigh prevents echo on the current command
echo The echo on/off turns on/off the echo command. Turn on for debugging
echo Paths (only) with folder names with spaces need to be inclosed in         quotes (not the ommand)
goto :done

:docs
echo executing "%homedrive%%homepath%\Documents"
%homedrive%
cd "%homepath%\Documents"\test error\
if %errorlevel% neq 0 goto :error
goto :done

:error
echo Error: Input (%1 %2 %3 %4 %5 %6 %7 %8 %9) or command is invalid
echo go help for help
goto :done

:done