Comment amener Vim à mettre en évidence les caractères non-ascii?

J'essaie de faire en sorte que Vim mette en évidence les caractères non ASCII. Existe-t-il un paramètre, un modèle de recherche regex ou un plugin disponible pour le faire?

En utilisant la plage dans une []classe de caractères dans votre recherche, vous devriez pouvoir exclure la plage de caractères hexadécimaux ASCII, mettant ainsi en évidence (en supposant que vous avez hlsearchactivé) tous les autres caractères situés en dehors de la plage ASCII:

/[^\x00-\x7F]

Cela fera une correspondance négative (via [^]) pour les caractères entre ASCII 0x00et ASCII 0x7F(0-127), et semble fonctionner dans mon test simple. Pour l'ASCII étendu, bien sûr, étendez la plage jusqu'à au \xFFlieu de l' \x7Futiliser /[^\x00-\xFF].

Vous pouvez également l'exprimer en décimal via \d:

/[^\d0-\d127]

Si vous avez besoin de quelque chose de plus spécifique, comme l'exclusion des caractères non imprimables, vous devrez ajouter ces plages dans la classe de caractères [].

Oui, il existe une fonctionnalité native pour mettre en évidence toutes les chaînes correspondantes. Dans Vim, faites:

:help highlight
:help syn-match

syn-matchdéfinit une chaîne qui correspond à tomber dans un groupe. highlightdéfinit la couleur utilisée par le groupe. Pensez simplement à la coloration syntaxique de vos fichiers vimrc.

Vous pouvez donc utiliser les commandes ci-dessous dans votre fichier .vimrc:

syntax match nonascii "[^\x00-\x7F]"
highlight nonascii guibg=Red ctermbg=2

Pour les autres (à partir de maintenant moins malchanceux) qui se retrouvent ici via un moteur de recherche et ne peuvent pas mettre en évidence des caractères non ASCII, essayez ceci (mettez ceci dans votre .vimrc):

highlight nonascii guibg=Red ctermbg=1 term=standout
au BufReadPost * syntax match nonascii "[^\u0000-\u007F]"

Ceci a l'avantage supplémentaire de ne pas entrer en conflit avec les définitions de syntaxe régulières (basées sur le type de fichier [extension de fichier]).

Cette regex fonctionne également. C'était le premier hit google pour "vim remove non-ascii characters" de briceolion.com et :set hlsearchmettra en évidence:

/[^[:alnum:][:punct:][:space:]]/

Si vous êtes également intéressé par les caractères non imprimables , utilisez celui-ci:/[^\x00-\xff]/

Je l'utilise dans une fonction:

 function! NonPrintable()
   setlocal enc=utf8
   if search('[^\x00-\xff]') != 0
     call matchadd('Error', '[^\x00-\xff]')
     echo 'Non printable characters in text'
   else
     setlocal enc=latin1
     echo 'All characters are printable'
   endif
 endfunction

Sur la base des autres réponses sur ce sujet et de la réponse que j'ai ici, j'ai ajouté ceci à mon .vimrc, afin que je puisse contrôler la mise en évidence non-ascii en tapant <C-w>1. Il affiche également les commentaires internes, bien que vous deviez ajouter le groupe de commentaires pour chaque syntaxe de fichier que vous utiliserez. Autrement dit, si vous éditez un fichier zsh, vous devrez ajouter zshCommentà la ligne

au BufReadPost * syntax match nonascii "[^\x00-\x7F]" containedin=cComment,vimLineComment,pythonComment

sinon, il n'affichera pas le caractère non-ascii (vous pouvez également définir containsin = ALL si vous voulez être sûr d'afficher les caractères non-ascii dans tous les groupes). Pour vérifier comment le commentaire est appelé sur un type de fichier différent, ouvrez un fichier du type souhaité et entrez :sysur vim, puis recherchez les éléments de syntaxe pour le commentaire.

function HighlightNonAsciiOff()
  echom "Setting non-ascii highlight off"
  syn clear nonascii
  let g:is_non_ascii_on=0
  augroup HighlightUnicode
  autocmd!
  augroup end
endfunction

function HighlightNonAsciiOn()
  echom "Setting non-ascii highlight on"
  augroup HighlightUnicode
  autocmd!
  autocmd ColorScheme *
        \ syntax match nonascii "[^\x00-\x7F]" containedin=cComment,vimLineComment,pythonComment |
        \ highlight nonascii cterm=underline ctermfg=red ctermbg=none term=underline
  augroup end
  silent doautocmd HighlightUnicode ColorScheme
  let g:is_non_ascii_on=1
endfunction

function ToggleHighlightNonascii()
  if g:is_non_ascii_on == 1
    call HighlightNonAsciiOff()
  else
    call HighlightNonAsciiOn()
  endif
endfunction

silent! call HighlightNonAsciiOn()
nnoremap <C-w>1 :call ToggleHighlightNonascii()<CR>

Aucune des réponses ci-dessus n'a fonctionné pour moi.

Alors j'ai utilisé :1,$ s/[^0-9a-zA-Z,-_\.]//g

Il garde la plupart des personnages qui m'intéressent.

Quelqu'un a déjà répondu à la question. Cependant, pour d'autres qui rencontrent encore des problèmes, voici une autre solution pour mettre en évidence les caractères non-ascii dans les commentaires (ou tout autre groupe de syntaxe en la matière). Ce n'est pas le meilleur, mais c'est une solution temporaire.

On peut essayer:

:syntax match nonascii "[^\u0000-\u007F]" containedin=ALL contained |
            \ highlight nonascii ctermfg=yellow guifg=yellow

Cela a des pièces de mélange d'autres solutions. Vous pouvez supprimer contained, mais, de la documentation, il peut y avoir un problème potentiel de récurrence (si je comprends bien). Pour afficher d'autres modèles définis, la syn-containssection le contiendrait.

:help syn-containedin
:help syn-contains 

Problème répliqué depuis: définir l'élément sur une priorité de surbrillance plus élevée sur vim