Résoudre le chemin absolu à partir du chemin relatif et / ou du nom de fichier

Existe-t-il un moyen dans un script batch Windows de renvoyer un chemin absolu à partir d'une valeur contenant un nom de fichier et / ou un chemin relatif?

Donné:

"..\"
"..\somefile.txt"

J'ai besoin du chemin absolu par rapport au fichier batch.

Exemple:

• "somefile.txt" se trouve dans "C: \ Foo \"
• "test.bat" se trouve dans "C: \ Foo \ Bar".
• L'utilisateur ouvre une fenêtre de commande dans "C: \ Foo" et appelle Bar\test.bat ..\somefile.txt
• Dans le fichier de commandes "C: \ Foo \ somefile.txt" serait dérivé de %1

Dans les fichiers batch, comme dans les programmes C standard, l'argument 0 contient le chemin du script en cours d'exécution. Vous pouvez utiliser %~dp0pour obtenir uniquement la partie chemin du 0ème argument (qui est le script actuel) - ce chemin est toujours un chemin complet.

Vous pouvez également obtenir le chemin complet de votre premier argument en utilisant %~f1, mais cela donne un chemin en fonction du répertoire de travail courant, ce qui n'est évidemment pas ce que vous voulez.

Personnellement, j'utilise souvent l' %~dp0%~1idiome dans mon fichier batch, qui interprète le premier argument par rapport au chemin du batch en cours d'exécution. Il a cependant un inconvénient: il échoue lamentablement si le premier argument est pleinement qualifié.

Si vous avez besoin de supporter à la fois des chemins relatifs et absolus, vous pouvez utiliser la solution de Frédéric Ménez : changer temporairement le répertoire de travail courant.

Voici un exemple qui illustrera chacune de ces techniques:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

Si vous enregistrez ceci sous c: \ temp \ example.bat et que vous l'exécutez à partir de c: \ Users \ Public sous

c: \ Users \ Public> \ temp \ example.bat .. \ windows

... vous observerez la sortie suivante:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

la documentation de l'ensemble des modificateurs autorisés sur un argument batch peut être trouvée ici: https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/call

Je suis tombé sur un besoin similaire ce matin: comment convertir un chemin relatif en chemin absolu à l'intérieur d'un script de commande Windows.

Ce qui suit a fait l'affaire:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

La plupart de ces réponses semblent folles sur compliquées et super boguées, voici la mienne - cela fonctionne sur n'importe quelle variable d'environnement, non %CD%ou PUSHD/ POPDou for /fabsurde - juste de vieilles fonctions batch. - Le répertoire et le fichier ne doivent même pas exister.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~f1
  EXIT /B

Sans avoir à avoir un autre fichier batch auquel passer des arguments (et utiliser les opérateurs d'argument), vous pouvez utiliser FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

où iin %%~fiest la variable définie à /F %%i. par exemple. si vous changiez cela en /F %%aalors la dernière partie serait %%~fa.

Pour faire la même chose directement à l'invite de commande (et non dans un fichier batch), remplacez %%par %...

C'est pour aider à combler les lacunes de la réponse d'Adrien Plisson (qui devrait être votée pour dès qu'il la modifie ;-):

vous pouvez également obtenir le chemin complet de votre premier argument en utilisant% ~ f1, mais cela donne un chemin en fonction du chemin actuel, ce qui n'est évidemment pas ce que vous voulez.

malheureusement, je ne sais pas comment mélanger les 2 ensemble ...

On peut gérer %0et de %1même:

• %~dpnx0pour lecteur complet + chemin + nom + extension du fichier batch lui-même, cela
  %~f0suffit également;
• %~dpnx1pour lecteur complet + chemin + nom + extension de son premier argument [si c'est un nom de fichier du tout], cela
  %~f1suffit également;

%~f1fonctionnera indépendamment de la manière dont vous avez spécifié votre premier argument: avec des chemins relatifs ou avec des chemins absolus (si vous ne spécifiez pas l'extension du fichier lors du nommage %1, il ne sera pas ajouté, même si vous utilisez %~dpnx1- cependant.

Mais comment diable nommeriez-vous un fichier sur un lecteur différent de toute façon si vous ne donniez pas ces informations de chemin complet sur la ligne de commande en premier lieu?

Cependant, %~p0, %~n0, %~nx0et %~x0peut être utile, si vous êtes intéressé par chemin (sans driveletter), nom de fichier (sans extension), nom complet avec l' extension ou l'extension de nom de fichier uniquement. Mais notez que tandis que %~p1et %~n1fonctionnera pour trouver le chemin ou le nom du premier argument, %~nx1et %~x1n'ajoutera pas + afficher l'extension, sauf si vous l'avez déjà utilisé sur la ligne de commande.

Vous pouvez également utiliser les fonctions batch pour cela:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

Petite amélioration de l'excellente solution de BrainSlugs83 . Généralisé pour permettre de nommer la variable d'environnement de sortie dans l'appel.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

Si exécuter à partir de la C:\projectsortie est:

C:\project\doc\build

Je n'ai pas vu beaucoup de solutions à ce problème. Certaines solutions utilisent la traversée de répertoires à l'aide de CD et d'autres utilisent des fonctions de traitement par lots. Ma préférence personnelle a été pour les fonctions batch et en particulier, la fonction MakeAbsolute fournie par DosTips.

La fonction présente de réels avantages, principalement qu'elle ne modifie pas votre répertoire de travail actuel et d'autre part que les chemins en cours d'évaluation ne doivent même pas exister. Vous trouverez quelques conseils utiles sur la façon d'utiliser la fonction ici aussi.

Voici un exemple de script et ses sorties:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

Et la sortie:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

J'espère que cela aide ... Cela m'a certainement aidé :) PS Merci encore à DosTips! Tu gères!

Vous pouvez simplement les concaténer.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

cela semble étrange avec \ .. \ au milieu de votre chemin mais cela fonctionne. Pas besoin de faire quoi que ce soit de fou :)

Dans votre exemple, à partir de Bar \ test.bat, DIR / B / S .. \ somefile.txt renverrait le chemin complet.

PowerShell est assez courant ces jours-ci, donc je l'utilise souvent comme moyen rapide d'appeler C # car il a des fonctions pour à peu près tout:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

C'est un peu lent, mais la fonctionnalité gagnée est difficile à battre à moins de recourir à un langage de script réel.

La solution de stijn fonctionne avec les sous-dossiers sous C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

Fichiers Voir toutes les autres réponses

Répertoires

En ..étant votre chemin relatif, et en supposant que vous êtes actuellement dans D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (le chemin relatif)

renvoie le chemin absolu, par exemple

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b