UltiSnips et YouCompleteMe

J'ai des bundles ultisnips et youcompleteme installés sur mon macvim. Le problème est que ultisnips ne fonctionne pas car tab est lié par ycm. J'ai essayé de faire en let g:UltiSnipsExpandTrigger = "<s-tab>"sorte que je puisse déclencher l'achèvement de l'extrait avec shift-tab, mais cela ne fonctionne pas pour une raison inconnue. Je pourrais utiliser des bouchons comme déclencheur, mais jusqu'à présent, je n'ai trouvé aucun moyen de le faire.

L'un d'entre vous utilise-t-il ces deux modules complémentaires ensemble? Que puis-je faire pour que l'onglet shift fonctionne? Pouvez-vous recommander une autre clé pour déclencher des extraits?

Une autre option consiste à utiliser le plugin SuperTab:

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Ici, YouCompleteMe est lié à une combinaison différente Ctrln, mais cette combinaison est liée à l'onglet via SuperTab. UltiSnips et SuperTab fonctionnent bien ensemble, vous pouvez donc simplement lier UltiSnips à l'onglet directement et tout fonctionnera.

Essayez cette suggestion sur un page de l'outil de suivi des problèmes YouCompleteMe. Dans votre .vimrc:

let g:UltiSnipsExpandTrigger="<c-j>"

Bien que ce paramètre fasse en sorte que l'expansion d'un extrait de code partage le mappage par défaut pour sauter en avant dans un extrait de code , il simule le comportement de TextMates comme indiqué dans les balises d'aide d'UltiSnips.

Depuis que j'ai mappé ma touche de verrouillage des majuscules à Ctrl, ce mappage fonctionne assez bien.

copiez le code suivant dans votre vimrc et profitez-en. Cette fonction gérera tous les problèmes entre YCM et UltiSnips.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

j'ai ceci dans mon vimrc

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

c'est ce que j'ai fait lors de mon premier essai, mais j'ai mal orthographié UltiSnips avec Ultisnips .. eh bien, a fonctionné à la fin!

J'ai personnellement choisi de ne pas utiliser <tab>avec YouCompleteMe mais de naviguer manuellement.

J'ai donc ajouté ceci à mon .vimrc:

let g:ycm_key_list_select_completion=[]
let g:ycm_key_list_previous_completion=[]

qui désactive simplement la tabclé pour YCM. À la place, vous utilisez les touches de déplacement (flèches ou CTRL-N/ CTRL-P) et sélectionnez l'entrée avec CR. UltiSnips fonctionne par défaut avec tab.

Juste en rassemblant les réponses de Michaelslec, Joey Liu et avec les solutions que j'ai trouvées dans ce fil de discussion et le vimrc de ce gars , j'ai maintenant cela qui a résolu à peu près tous les problèmes.

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippet()
  if g:ulti_expand_res == 0
    if pumvisible()
      return "\<C-n>"
    else
      call UltiSnips#JumpForwards()
      if g:ulti_jump_forwards_res == 0
        return "\<TAB>"
      endif
    endif
  endif
  return ""
endfunction

function! g:UltiSnips_Reverse()
  call UltiSnips#JumpBackwards()
  if g:ulti_jump_backwards_res == 0
    return "\<C-P>"
  endif

  return ""
endfunction


if !exists("g:UltiSnipsJumpForwardTrigger")
  let g:UltiSnipsJumpForwardTrigger = "<tab>"
endif

if !exists("g:UltiSnipsJumpBackwardTrigger")
  let g:UltiSnipsJumpBackwardTrigger="<s-tab>"
endif

au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger     . " <C-R>=g:UltiSnips_Complete()<cr>"
au InsertEnter * exec "inoremap <silent> " .     g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Bien que je sache que cet article est un peu vieux, j'ai ma propre fonction qui est un peu plus optimisée que celle donnée ci-dessus:

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Bien sûr, si vous gardez simplement les paramètres fournis par Joey Liu et que vous utilisez simplement cette fonction, tout fonctionnera parfaitement!

EDIT: J'utilise également une autre fonction pour augmenter la fonctionnalité de recul entre YouCompleteMe et UltiSnips. Je vais vous montrer ce que je veux dire:

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Ensuite, mettez simplement ceci dans votre .vimrc:

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Ainsi que let g:UltiSnipsJumpBackwardTrigger="<s-tab>"et votre ensemble!

J'utilise les deux ensemble. Par défaut, YouCompleteMe lie <Tab>et <Down>pour sélectionner l'élément d'achèvement suivant et aussi <S-Tab>et <Up>pour sélectionner l'élément d'achèvement précédent. Vous pouvez modifier les liaisons YouCompleteMe avec les options g: ycm_key_list_select_completion et g: ycm_key_list_previous_completion . Notez que les noms de ces options ont été récemment modifiés lorsque l'option est passée d'une chaîne unique à une liste de chaînes.

J'ai installé le plugin UltiSnips après le plugin YouCompleteMe donc j'ai pensé qu'ils étaient en conflit, mais en réalité j'avais quelque chose de plus interférant:

set paste

Assurez-vous de le supprimer .vimrcs'il est présent.

Bien que Many answer fonctionne correctement dans cet article, je veux juste dire que le problème est causé par une collision de liaison de clé entre YCM et UltiSnip, alors que YCM prend en charge les extraits UltiSnip par défaut, il prend le déclencheur d'extension UltiSnip par défaut <tab>comme touche de sélection d'achèvement, donc Les extraits de code UltiSnip ne seront pas développés par <tab>. Leur donner une liaison de clé différente résoudra le problème, j'utilise personnellement <c-net <c-p>pour YCM et j'utilise la valeur <tab>par défaut pour UltiSnip. Vous pouvez obtenir plus de détails avec help youcompletemedoc dans vim.

Sur la base de la réponse de Siegfried, j'utilise ce qui suit qui semble plus naturel:

let g:ycm_key_list_select_completion = ['<C-j>']
let g:ycm_key_list_previous_completion = ['<C-k>']

let g:UltiSnipsExpandTrigger = "<C-l>"
let g:UltiSnipsJumpForwardTrigger = "<C-j>"
let g:UltiSnipsJumpBackwardTrigger = "<C-k>"

J'utilise également les c-hjklliaisons ailleurs (passage d'un volet à un autre), mais ce ne serait qu'en mode normal, donc il n'y a pas de problème.

J'utilise ;pour développer UltiSnips, c'est tellement chouette pour moi

let g:UltiSnipsExpandTrigger = ";"

J'utilise kj. Voici ce qu'il y a dans mon .vimrc:

let g:UltisnipsExpandTrigger="kj".

Il m'arrive rarement de tomber sur un mot qui contient kj. Si tel est le cas, j'attendrais juste quelques secondes après avoir tapé ket ce type j.

Comme mentionné par d'autres, mapper Cj aux ultisnips fonctionne très bien.
let g:UltiSnipsExpandTrigger="<c-j>"

Maintenant, si vous allez un peu plus loin et installez xcape et utilisez
xcape -e "Shift_L=Control_R|J"

Vous libérez la puissance d'utiliser uniquement la touche Maj pour les utlitsnips.