'La valeur du symbole en tant que variable est nulle' dans le rappel depuis url-retrieve

Lors de l'exécution de ce qui suit, j'obtiens une erreur:

(defun caller (func)
  (url-retrieve "http://m0smith.freeshell.org/"
   (lambda (status) (funcall func))))


(caller (lambda() (message "called")))

Résultat:

error in process filter: Symbol's value as variable is void: func

Quelle est la meilleure façon de résoudre ce problème? Fondamentalement, je dois accepter un rappel ailleurs, l'envelopper dans un autre lambda et l'utiliser comme rappel pour récupérer l'URL.

Si je change l'appelant en

(defun caller (func)
  (url-retrieve "http://m0smith.freeshell.org/"
   `(lambda (status) (funcall ,func))))

Ça marche. Cependant, je ne peux pas le faire car le func est passé par flycheck et l'expansion de la macro le brise. Pour voir le contexte complet de ce que je fais: https://gist.github.com/m0smith/b5961fda6afd71e82983

Vous pouvez y parvenir localement en utilisant le lexical-let de cl.el :

(eval-when-compile '(require 'cl))

(defun my-test-caller (func)
  (lexical-let ((ext-func func))
    (url-retrieve "http://www.google.com"
                  (lambda (status) (funcall ext-func)))))

(my-test-caller #'(lambda() (message "called")))

Pour être explicite comme le dit l'aide:

Like `let', but lexically scoped.
The main visible difference is that lambdas inside BODY will create
lexical closures as in Common Lisp.

Vous pouvez maintenant obtenir le même effet en activant la liaison lexicale qui a été ajoutée dans Emacs 24.1. Il s'agit d'une variable locale de tampon qui peut être définie et permettra des fermetures lexicales sur tout le code du tampon. Ainsi, votre tampon ressemblerait à ceci:

;; -*- lexical-binding: t; -*-

(defun my-lexical-test-caller (func)
  (url-retrieve "http://www.google.com"
                (lambda (status) (funcall func))))

(my-lexical-test-caller
 #'(lambda()
     (message "called from lexical-binding def")))

Activer lexical-bindingpour votre bibliothèque, avec M-x add-file-local-variable-prop-line RET lexical-binding RET t.

Veuillez ne pas utiliser lexical-letcomme suggéré par l'autre réponse. Flycheck lui-même n'est pas compatible avec Emacs 23, il est donc inutile d'essayer de maintenir la compatibilité Emacs 23 dans votre propre code.