Comment récupérer des docstrings à partir de fonctions et de variables?

J'essaie d'écrire une fonction qui récupérera les docstrings de n'importe quel sexps dans un fichier qui correspond (def.*).

Je voudrais pouvoir à la fois récupérer toutes les fonctions / macros, ainsi que toutes les variables définies. Pour les variables, je voudrais la docstring, tandis que pour toutes les fonctions, je voudrais également les listes d'arguments.

Si l'objectif est d'obtenir des informations sur les fonctions et variables déjà présentes dans l'environnement :

• Pour les docstrings de fonctions et de macros, voir la documentationfonction.

• Pour les docstrings variables, utilisez documentation-property; par exemple:

  (documentation-property
   'user-init-file 'variable-documentation)
  

• Pour l'arité de la fonction et la liste des arguments, consultez cette question Emacs.SE , la réponse et les commentaires sur la question.

(J'ai trouvé cela en appuyant C-h k C-h fet en survolant le code source de describe-function(idem pour les docstrings variables, mais en étudiant describe-variable).)

Pour analyser un fichier de code source Emacs Lisp, en supposant que le but est d'obtenir des informations sur les def.*formulaires de niveau supérieur , on peut faire quelque chose de semblable au suivant.

(defun get-defun-info (buffer)
  "Get information about all `defun' top-level sexps in a buffer
BUFFER. Returns a list with elements of the form (symbol args docstring)."
  (with-current-buffer buffer
    (save-excursion
      (save-restriction
        (widen)
        (goto-char (point-min))
        (let (result)
          ;; keep going while reading succeeds
          (while (condition-case nil
                     (progn
                       (read (current-buffer))
                       (forward-sexp -1)
                       t)
                   (error nil))
            (let ((form (read (current-buffer))))
              (cond
               ((not (listp form))      ; if it's not a list, skip it
                nil)
               ((eq (nth 0 form) 'defun) ; if it's a defun, collect info
                (let ((sym (nth 1 form))
                      (args (nth 2 form))
                      (doc (when (stringp (nth 3 form)) (nth 3 form))))
                  (push (list sym args doc) result))))))
          result)))))

Ceci peut être facilement étendu à defvar, defconstetc.

Pour gérer l' defunapparition à l' intérieur de formulaires de niveau supérieur, il faudrait descendre dans ces formulaires, éventuellement en utilisant la récursivité.