Comment remplacer les liaisons en mode majeur

Parfois, mes combinaisons de touches globales sont remplacées par un mode majeur. Un exemple simple est le paramètre suivant dans mon fichier init

(global-set-key (kbd "C-j") 'newline-and-indent)

Mais, ce qui est gênant, cette liaison est masquée par le mode majeur "Lisp Interaction", qui est le mode par défaut du tampon de travail.

Lorsque je me trouve dans une situation où un mode majeur (ou un mode mineur) masque ma liaison de clé globale, comment puis-je la récupérer?

Note: Ma question n'est pas « Comment puis - je lier C-jà newline-and-indent« ? Mode » dans » Lisp Interaction Je suis intéressé par une réponse beaucoup plus générale sur la façon de traiter les keymaps en conflit ou les associations de touches utilisateur qui sont masquées par un mode majeur / mineur.

Il existe également une approche de "raccourci" pour la même solution si vous ne souhaitez pas définir votre propre mode mineur (dont je parle dans ma première réponse).

Vous pouvez installer le use-packagepackage disponible à partir Melpa et utiliser bind-key*ou bind-keys*macro qui fait partie du bind-keypaquet qui est livré avec use-package.

De la documentation de bind-key.el:

;; If you want the keybinding to override all minor modes that may also bind
;; the same key, use the `bind-key*' form:
;;
;;   (bind-key* "<C-return>" 'other-window)

;; To bind multiple keys in a `bind-key*' way (to be sure that your bindings
;; will not be overridden by other modes), you may use `bind-keys*' macro:
;;
;;    (bind-keys*
;;     ("C-o" . other-window)
;;     ("C-M-n" . forward-page)
;;     ("C-M-p" . backward-page))

Vous pouvez définir votre propre mode mineur et sa carte de touches et faire en sorte que ceux-ci remplacent tous les autres modes (mineur + majeur). C'est exactement pourquoi j'ai choisi d'écrire mon propre mode mineur.

Étapes à suivre pour que vos liaisons de clé remplacent toutes les liaisons:

• Définissez votre propre mode mineur et votre carte de touches comme indiqué ci-dessous.
• Activer votre mode mineur globalement
• (define-key my-mode-map (kbd "C-j") #'newline-and-indent)

De même, les autres raccourcis clavier définis dans votre mode mineur remplaceront ceux des autres modes.

Je recommande fortement de lire le billet de blog de Christopher Wellons sur la façon d'écrire un mode mineur. Ce blog, ajouté à la contrariété de devoir définir plusieurs raccourcis clavier nildans plusieurs modes majeurs et mineurs, m'a incité à écrire mon propre mode mineur.

La meilleure partie de cette approche est que, lorsque vous voulez vérifier ce que les raccourcis-clés font dans la configuration par défaut d’emacs, vous désactivez simplement le mode mineur; vous le rallumez et vous retrouvez vos raccourcis clavier personnalisés.

;; Main use is to have my key bindings have the highest priority
;; https://github.com/kaushalmodi/.emacs.d/blob/master/elisp/modi-mode.el

(defvar my-mode-map (make-sparse-keymap)
  "Keymap for `my-mode'.")

;;;###autoload
(define-minor-mode my-mode
  "A minor mode so that my key settings override annoying major modes."
  ;; If init-value is not set to t, this mode does not get enabled in
  ;; `fundamental-mode' buffers even after doing \"(global-my-mode 1)\".
  ;; More info: http://emacs.stackexchange.com/q/16693/115
  :init-value t
  :lighter " my-mode"
  :keymap my-mode-map)

;;;###autoload
(define-globalized-minor-mode global-my-mode my-mode my-mode)

;; https://github.com/jwiegley/use-package/blob/master/bind-key.el
;; The keymaps in `emulation-mode-map-alists' take precedence over
;; `minor-mode-map-alist'
(add-to-list 'emulation-mode-map-alists `((my-mode . ,my-mode-map)))

;; Turn off the minor mode in the minibuffer
(defun turn-off-my-mode ()
  "Turn off my-mode."
  (my-mode -1))
(add-hook 'minibuffer-setup-hook #'turn-off-my-mode)

(provide 'my-mode)

;; Minor mode tutorial: http://nullprogram.com/blog/2013/02/06/

Pour qu'une liaison globale remplace une liaison en mode majeur, définissez simplement la liaison sur nildans le mode majeur:

(define-key my-major-mode-map (kbd "C-j") nil)

Il n’est pas possible d’avoir la liaison globale prioritaire sur tous les modes en général (sinon il ne servirait à rien d’avoir des modes majeurs), mais vous pouvez le contourner en créant votre propre mode mineur avec vos liaisons les plus importantes. Dans ce cas, vous auriez au moins préséance sur la plupart des modes (mais pas nécessairement sur tous).

Vous pouvez utiliser ces macros:

(defmacro expose-global-keybinding (binding map)
  `(define-key ,map ,binding (lookup-key (current-global-map) ,binding)))

(defmacro expose-bindings (map bindings)
  `(dolist (bnd ,bindings)
     (expose-global-keybinding (kbd bnd) ,map)))

EDIT :

Vérifiez l'exemple ci-dessous:

Si le clavier X supprime votre liaison globale Y, vous écrivez:

(expose-bindings X '("Y"))

Et alors la dérogation sera «annulée».