Insertion automatique des dernières valeurs d'indice / exposant utilisées dans les formules mathématiques

J'utilise AUCTeX pour la définition de textes mathématiques. Souvent, je dois taper des équations avec des sommes, des intégrales, etc. qui ont tous les mêmes sous-indices ou indices. Je voudrais remplir automatiquement le sous-indice / exposant actuel avec la valeur qu'il avait avant. Exemple:

\sum_{i=1}^{\infty} a_i = \sum…

Quand j'appuie sur _l'équation ci-dessus, Emacs devrait écrire _{i=1}. Facultatif, il serait bon que le deuxième exposant soit également rempli.

Comment réaliser cela?

Ajoutez à votre fichier init:

(defvar mg-TeX-insert-subscript-history nil)
(defvar mg-TeX-insert-superscript-history nil)

(defun TeX-insert-sub-or-superscript (arg)
  "Insert typed key ARG times and possibly a pair of braces.
Brace insertion is only done if point is in a math construct and
`TeX-electric-sub-and-superscript' has a non-nil value."
  (interactive "*p")
  (self-insert-command arg)
  (when (and TeX-electric-sub-and-superscript (texmathp))
    (let* ((history (cond
             ((equal last-input-event ?_)
              'mg-TeX-insert-subscript-history)
             ((equal last-input-event ?^)
              'mg-TeX-insert-superscript-history)))
       (content (read-string "Content: " (car (symbol-value history)) history)))
      (insert (concat TeX-grop content TeX-grcl))
      (if (zerop (length content))
      (backward-char)))))

Assurez-vous qu'il TeX-electric-sub-and-superscriptest défini sur non nul.

Voici une version qui insère de manière non interactive le dernier sous-script / super-script apparaissant pour le jeton au point:

(defun my/electric-sub-super-script (arg)
  "Insert typed character ARG times and possibly a sub/super-script.
Sub/super-script insertion is done only in a (La)TeX math mode region.
The inserted sub/super-script is copied from the last occurence of a
sub/superscript for the token at point."
  (interactive "p")
  (self-insert-command arg)
  (when (texmathp)
    (insert
     (save-excursion
       (let ((current-token (let ((end (point)))
                              (backward-sexp 1)
                              (buffer-substring-no-properties (point) end))))
         (if (search-backward current-token nil t)
             (progn
               (search-forward current-token)
               (let ((begin (point)))
                 (forward-sexp 1)
                 (buffer-substring-no-properties begin (point))))
           ""))))))

(define-key TeX-mode-map (kbd "_") #'my/electric-sub-super-script)
(define-key TeX-mode-map (kbd "^") #'my/electric-sub-super-script)

En prenant l'exemple de la question, voici la séquence des états du tampon obtenue en commençant par la première ligne et en tapant _^SPCa_:

\sum_{i=1}^{\infty} a_i = \sum▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty}▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a▮
\sum_{i=1}^{\infty} a_i = \sum_{i=1}^{\infty} a_i▮