Copier du texte d'Emacs dans le presse-papiers OS X

Lorsque j'exécute Emacs dans un terminal texte au lieu du mode GUI normal, je peux copier dans Emacs en activant le début d'une région avec C-SPC, puis sélectionner ce que je veux, puis faire M-w.

Existe-t-il un moyen de copier une région de cette manière dans le presse-papiers OSX pour la coller, par exemple dans une page Web (autrement qu'en exécutant Emacs en mode GUI, évidemment)?

Je ne suis pas intéressé à créer un raccourci différent pour cela, et idéalement, cela ne devrait pas nécessiter l'installation de modules.

J'ai vu ce post et essayé la réponse acceptée, mais cela ne fonctionne pas semble fonctionner comme je m'y attendais ci-dessus.

D'autres idées?

Copie d'Emacs dans le presse-papiers OS X:

sélectionnez la région puis M-| pbcopy RET

Coller du presse-papiers OS X vers Emacs:

C-u M-| pbpaste RET (remplace la région actuelle si elle existe)

Explication:

M-|s'exécute shell-command-on-region, ce qui, comme son nom l'indique, dirige la région actuelle vers une commande shell. C-u M-|fait la même chose, mais remplace la région actuelle par stdoutla commande en cours d'exécution.

pbcopyet pbpastesont des utilitaires OS X pour accéder au presse-papiers du système.

Ce qui suit fonctionne, copié d' ici

(defun copy-from-osx ()
  (shell-command-to-string "pbpaste"))

(defun paste-to-osx (text &optional push)
  (let ((process-connection-type nil))
    (let ((proc (start-process "pbcopy" "*Messages*" "pbcopy")))
      (process-send-string proc text)
      (process-send-eof proc))))

(setq interprogram-cut-function 'paste-to-osx)
(setq interprogram-paste-function 'copy-from-osx)

Si vous utilisez Emacs "de façon normale" (c'est-à-dire comme une application GUI), il devrait déjà le faire par défaut. Si vous utilisez Emacs dans un émulateur de terminal, alors il ne sait pas comment le faire par défaut, mais vous pouvez installer le xclippackage à partir de GNU ELPA puis activer le xclip-modequi enseigne à Emacs comment le faire à la fois pour GNU / Linux et pour OSX.

Comme l'a dit Stefan, les applications graphiques Emacs devraient le faire par défaut.

Dans un terminal texte, une autre option consiste à utiliser des fonctions comme celle-ci:

(defun pbcopy ()
  (interactive)
  (let ((deactivate-mark t))
    (call-process-region (point) (mark) "pbcopy")))

(defun pbpaste ()
  (interactive)
  (call-process-region (point) (if mark-active (mark) (point)) "pbpaste" t t))

(defun pbcut ()
  (interactive)
  (pbcopy)
  (delete-region (region-beginning) (region-end)))

Voici une fonction elisp simple que vous pouvez placer dans votre fichier .emacs qui copie le contenu du tampon dans lequel vous vous trouvez dans le presse-papiers. Vous n'avez rien à sélectionner, il copie tout. Le code est court et assez explicite.

(defun xclip ()
(interactive)
(shell-command (concat "cat " (buffer-file-name (window-buffer (minibuffer-selected-window))) " | pbcopy")))

Découvrez clipboard-kill-regionet clipboard-yank. Ils viennent de menu-bar.el.

Une fois qu'une région est mise en surbrillance, vous pouvez utiliser clipboard-kill-region pour tuer la région à la fois dans votre tampon de collage et dans le presse-papiers du système. clipboard-yank "colle" tout ce qui se trouve actuellement dans le presse-papiers du système.

La réponse de Galder Zamarreño est excellente, cependant, elle brise le putcomportement diabolique en mode diabolique. Je l'ai donc adapté un peu plus bas - je suis sûr que ça pourrait être mieux, mais ça fait le boulot pour moi. N'hésitez pas à suggérer des améliorations:

(defun copy-from-osx ()
  (shell-command-to-string "pbpaste"))

(defun paste-to-osx (text &optional push)
  (let ((process-connection-type nil))
    (let ((proc (start-process "pbcopy" "*Messages*" "pbcopy")))
      (process-send-string proc text)
      (process-send-eof proc))))

----> Nouveau code

  (defun clipboard-on ()
    (interactive)
    (setq interprogram-cut-function 'paste-to-osx)
    (setq interprogram-paste-function 'copy-from-osx))
  (defun clipboard-off ()
    (interactive)
    (setq interprogram-cut-function 'gui-select-text)
    (setq interprogram-paste-function 'gui-selection-value))
  (global-set-key (kbd "C-c C-p") 'clipboard-on)
  (global-set-key (kbd "C-c C-y") 'clipboard-off))