Comment définir ⌘ + H pour activer l'affichage des fichiers cachés

Je veux que mon Mac affiche les fichiers cachés lorsque je tape sur ⌘ + H (comme ubuntu). Je peux voir les fichiers cachés en mettant cette defaults write com.apple.finder AppleShowAllFiles YEScommande dans le terminal mais je veux obtenir un raccourci clavier pour cela. De plus, si ⌘ + H est déjà utilisé par un autre processus, veuillez me faire savoir quel pourrait être le raccourci le plus proche et le plus connexe pour ce nouveau processus et comment l'attribuer au processus respectif, afficher les fichiers cachés.

Edit at Nov 2018
Tout cela est désormais sans objet depuis High Sierra. Dans le Finder, Cmd ⌘ Shift ⇧ . [point, point final] basculera les fichiers invisibles à la volée, rien d'autre n'est nécessaire.

Cmd ⌘ H est le raccourci à l'échelle du système pour "Masquer l'application la plus en avant"

Pour essayer de lier un nouveau raccourci à cela, vous pouvez peut-être utiliser Automator pour ajouter un service - mais je ne sais toujours pas comment vous pourriez le persuader de remplacer le système par défaut existant.

Cela fonctionne comme un service si vous utilisez une clé non système, mais pas avec Cmd ⌘ H

on run {input, parameters}

    set newHiddenVisiblesState to "YES"
    try
        set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
        if oldHiddenVisiblesState is in {"1", "YES"} then
            set newHiddenVisiblesState to "NO"
        end if
    end try
    do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState


    tell application "Finder"
        set theWindows to every Finder window
        repeat with i from 1 to number of items in theWindows
            set this_item to item i of theWindows
            set theView to current view of this_item
            if theView is list view then
                set current view of this_item to icon view
            else
                set current view of this_item to list view

            end if
            set current view of this_item to theView
        end repeat
    end tell

    return input
end run

Modifier pour El Capitan…
J'ai remarqué que l'actualisation de la fenêtre du Finder ne fonctionne plus dans El Capitan, il s'agit donc d'une version modifiée, en quittant le Finder à la place.

on run {input, parameters}      
    --Toggle Invisibles, El Capitan Version     
set newHiddenVisiblesState to "YES"
try
    set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    if oldHiddenVisiblesState is in {"1", "YES"} then
        set newHiddenVisiblesState to "NO"
    end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState & "; killall Finder"
end run

Je suppose que vous pouvez le faire fonctionner uniquement pour le Finder, si vous avez spécifié un autre raccourci clavier pour masquer le Finder - car il est visible en tant qu'élément de menu, il serait possible de remplacer pour cette application seule [en mettant quelque chose d'inutile comme alternative], vous laissant libre d'utiliser puis Cmd ⌘ H de basculer les invisibles du Finder uniquement.

Testé - fonctionne de cette façon

Cmd ⌘ Shift ⇧ . basculera l'affichage des fichiers cachés dans le Finder (dans Sierra ou version ultérieure (mais fonctionne dans la boîte de dialogue de fichier ouvert dans les versions antérieures)).